Extract texts between []

[eduzs]

I need to extract texts between [] in a string and save in a array:
For example: MyStr = "This is [name] and [number]"
Result array: MyArray = ["name","number"]
Any idea how to to this with vba?
Thanks!

 

[lrobbo314]

Sub Main()
Results = getBrackets("This is [name] and [number]")
End Sub

Function getBrackets(mySTR As String)
Dim SD As Object:   Set SD = CreateObject("Scripting.Dictionary")

With CreateObject("VBScript.RegExp")
    .Global = True
    .Pattern = "\[(\w+)\]"
    Set matches = .Execute(mySTR)
    For Each m In matches
        SD.Add m.submatches(0), Nothing
    Next m
End With

getBrackets = Application.Transpose(SD.keys())

End Function

 

[JEC]

Here a variation

Sub main()
Dim ar
ar = getBrackets("This is [name] and [number]")
End Sub

Function getBrackets(c As String) As Variant
  With CreateObject("vbscript.regexp")
    .Global = True
    .Pattern = "\[(\w+)\]"
    getBrackets = Split(Join(Filter(Split(.Replace(c, "#$1@#"), "#"), "@", 1), ""), "@")
 End With
End Function

 

[Peter_SSs]

Yet another slight variation

Sub Between_Brackets()
  Dim MyArray As Variant
  Const MyStr As String = "This is [name] and [number]"
  
  With CreateObject("VBScript.RegExp")
    .Global = True
    .Pattern = "\][^[]*\["
    MyArray = .Replace("]" & MyStr & "[", "]")
    MyArray = Split(Mid(MyArray, 2, Len(MyArray) - 2), "]")
  End With
End Sub

 

[RoryA]

Yet another alternative

Function SplitBracketedText(InputText As String) As String()
   Dim parts
   parts = Filter(Split(InputText, "["), "]")
   Dim n As Long
   For n = LBound(parts) To UBound(parts)
      parts(n) = Split(parts(n), "]")(0)
   Next n
   SplitBracketedText = parts
End Function

 

[JEC]

Here a one liner : )

Function getBrackets(c As String) As Variant
getBrackets = Split(Replace(Replace(Join(Filter(Split(Replace(Replace(c, "[", "@["), "]", "]@"), "@"), "["), "@"), "[", ""), "]", ""), "@")
End Function

 

[lrobbo314]

This was the fastest version I could come up with.

Function kk(ByVal s As String)
Dim res() As String
Dim beg As Integer
Dim lst As Integer

ReDim res(1 To Len(s) - Len(Replace(s, "[", "")))

For i = 1 To UBound(res)
    beg = InStr(s, "[") + 1
    lst = InStr(s, "]")
    res(i) = Mid(s, beg, lst - beg)
    s = Right(s, Len(s) - lst)
Next i

kk = res
End Function

 

[eduzs]

Thanks all! Superb!