fill for range, then use new value after blanks

[Slowy]

i have a phone log where A3 is the persons name
column B contains the data
at the end of the persons data in b, i have blanks
then starts a new persons phone records
number of calls vary per person
the persons name is only on the first line of the data that is in B

what i would like to is
Copy the persons name all the way down for every row in B that has data

i cannot figure out how to get the name to CHANGE once i hit a new name

thank you in advance

 

[Joe4]

If I understand you correctly, I think this should work:

Sub MyInsertNames()
'   Copy down names into blank cells in column A and for all entries in column B (starting at row 3)
 
    Dim myLastRow As Long
    Dim i As Long
    Dim myName As String
    
    Application.ScreenUpdating = False
    
'   Find last row with data in column B
    myLastRow = Cells(Rows.Count, "B").End(xlUp).Row
    
'   Loop from row 3 to end populating blank data in column A
    For i = 3 To myLastRow
        If Len(Cells(i, "A")) > 0 Then
            myName = Cells(i, "A")
        Else
            If Len(Cells(i, "B")) > 0 Then Cells(i, "A") = myName
        End If
    Next i
    
    Application.ScreenUpdating = True
    
End Sub