Find and Mark

[jackt05]

Hi friends,

I have to manually enter the code nos. of the hard copy to find the code in the soft copy. After finding the number, I wish to mark it as so that double work should not be done or to find which code's hard copy is not with me.
I am using Find and Replace to find the number and after it is found I have to click the replace tab to enter colour in it.
Is there any auto function to mark as soon as I find the required number instead of clicking the replace tab to save my time.

Regards and thanks in advance

 

[VoG]

Try

Sub FindHighlight()
Dim tempCell As Range, Found As Range, FoundRange As Range, sTxt As String
sTxt = InputBox("Search string")
If sTxt = "False" Then Exit Sub
Set Found = Range("A1")
Set tempCell = Cells.Find(what:=sTxt, After:=Found, SearchDirection:=xlNext, MatchCase:=False, lookat:=xlWhole)
If tempCell Is Nothing Then
    MsgBox prompt:="Not found", Title:="Finder"
    Exit Sub
Else
    Set Found = tempCell
    Set FoundRange = Found
End If
Do
    Set tempCell = Cells.FindNext(After:=Found)
    If Found.Row >= tempCell.Row Then Exit Do
    Set Found = tempCell
    Set FoundRange = Application.Union(FoundRange, Found)
Loop
FoundRange.Interior.ColorIndex = 6
FoundRange.Font.ColorIndex = 3
End Sub

 

[jackt05]

Now it is exactly highlighting the given no.,

can I find the nos. only in column B how can that be done and will the cursor not select the cell found.

thanks for the reply

 

[VoG]

Try

Sub FindHighlight()
Dim tempCell As Range, Found As Range, FoundRange As Range, sTxt As String
sTxt = InputBox("Search string")
If sTxt = "False" Then Exit Sub
Set Found = Range("B1")
Set tempCell = Columns("B").Find(what:=sTxt, After:=Found, SearchDirection:=xlNext, MatchCase:=False, lookat:=xlWhole)
If tempCell Is Nothing Then
    MsgBox prompt:="Not found", Title:="Finder"
    Exit Sub
Else
    Set Found = tempCell
    Set FoundRange = Found
End If
Do
    Set tempCell = Columns("B").FindNext(After:=Found)
    If Found.Row >= tempCell.Row Then Exit Do
    Set Found = tempCell
    Set FoundRange = Application.Union(FoundRange, Found)
Loop
With FoundRange
    .Interior.ColorIndex = 6
    .Font.ColorIndex = 3
    .Select
End With
End Sub

 

[jackt05]

Thank You,

Everything is perfect.

Thanks Once again

Jackt05