Finding a minimum using conditions and filters

[bbhgroup]

I have three columns of information:
Date, Plant, Load Start (Time)

I allow filters so that the user can select some of the data to evaluate.

I am looking for the Minimum value of Load Start (a time) based on Date and Plant Criteria.
For the following:
DB_DATE is the column array of dates
DB_PL is the column array of Plants
DB_LS is the column array of Load Start
All arrays are the same size.
<date> [date] is the cell with the desired date
[plant]is a cell with the desired plant

This formula works swell but doesn't take filters into account:
<code><code>
=MIN(IF(DB_DATE=<date>[date],IF(DB_PL=[plant],DB_LS)))
</date></code></code>
This array formula only works if the *first* row of the array matches the criteria selected, it otherwise returns 0:
<code><code>
={(SUBTOTAL(5,OFFSET(DB_LS,ROW(DB_LS)-ROW([first row of DB_LS]),,1))*--(DB_PL=[plant])*--(DB_DATE=[date]<date>))}
</date></code></code>
I also tried sumproduct/subtotal with unhappy results, this returns the sum of all the rows that match the criteria instead of the minimum one:
<code><code>
={SUMPRODUCT(SUBTOTAL(5,OFFSET(DB_LS,ROW(DB_LS)-ROW([first row of DB_LS)),,1)),--(DB_PL=[plant]),--(DB_DATE=[date]<date>))}
</date></code></code>

I'm stuck. I really thought the second formula should work but doesn't.</date>

 

[Domenic]

If you only have three columns, and you're applying the filter on the plant and date columns, try...

=SUBTOTAL(5,DB_LS)

Otherwise, try the following formula that needs to be confirmed with CONTROL+SHIFT+ENTER...

=MIN(IF(DB_PL=[plant],IF(DB_DATE=[date],IF(SUBTOTAL(3,OFFSET(DB_LS,ROW(DB_LS)-MIN(ROW(DB_LS)),0,1))>0,DB_LS))))

 

[bbhgroup]

It works SPECTACULARLY. What else can I say? Thank you very much!
I raise honey bees - send my your address to randywillaman@yahoo.com I'll send you a jar for the help...

 

[Domenic]

It works SPECTACULARLY. What else can I say? Thank you very much!

You're very welcome! Glad I could help!

I raise honey bees - send my your address to randywillaman@yahoo.com I'll send you a jar for the help...

Thank you, that's very kind of you. However, a simple thank you is more than enough. Thanks again.