Finding specific text and selecting

[chadski778]

I would like a macro to search my worksheet and find the cell containing "Actual%" and selecting the row that it is on as well as all rows of data below it. "Actual%" only appears once in my worksheet

Thanks

 

[VoG]

Perhaps

Sub Slct()
Dim LR As Long, Found As Range
LR = Cells.Find("*", SearchDirection:=xlPrevious, SearchOrder:=xlByRows).Row
Set Found = Cells.Find(what:="Actual%", LookIn:=xlValues, lookat:=xlWhole)
If Not Found Is Nothing Then Rows(Found.Row & ":" & LR).Select
End Sub

 

[chadski778]

Thanks, is it possible to reduce that selection down to columns F,G,H,I?

 

[VoG]

Try

Sub Slct()
Dim LR As Long, Found As Range
LR = Cells.Find("*", SearchDirection:=xlPrevious, SearchOrder:=xlByRows).Row
Set Found = Cells.Find(what:="Actual%", LookIn:=xlValues, lookat:=xlWhole)
If Not Found Is Nothing Then Range(Cells(Found.Row, 6), Cells(LR, 9)).Select
End Sub

Also, try posting your entire question in your initial post.

 

[chadski778]

Sorry I thought the last request would suffice but I couldn't paste the selection so I thought I'd better make it smaller

It works fine now

Thank you

 

[chadski778]

That was very useful thanks. Please could I have a modification on that macro so that the range of cells selected is limited up to the first empty row below ("Value%) rather then the last occupied row on the spreadsheet

Thanks

 

[VoG]

Try

Sub Slct()
Dim LR As Long, Found As Range
Set Found = Cells.Find(what:="Actual%", LookIn:=xlValues, lookat:=xlWhole)
If Found Is Nothing Then Exit Sub
LR = Found.End(xlDown).Row
Range(Cells(Found.Row, 6), Cells(LR, 9)).Select
End Sub

 

[chadski778]

It works great!

Thanks