Finding values <0.1 in column and deleting rows

[chadski778]

Please could you help me. I would like a macro that finds values in column D that equal <0.1 and then deletes the row that they are in?

Thanks

 

[njimack]

Sub Del_Rows()
Dim LR As Long
Dim i As Long

Application.ScreenUpdating = False

With Sheets("Sheet1") 'change sheetname as required
    LR = .Range("D" & Rows.Count).End(xlUp).Row
    
    For i = LR To 1 Step -1
        If .Cells(i, 4) < 0.1 Then .Rows(i).Delete
    Next i
End With

Application.ScreenUpdating = True

End Sub

 

[Rick Rothstein]

Here is a macro you can try...

Sub DeleteRowsLessThanPointOne()
  Dim UnusedColumn As Long, LastRow As Long
  Const StartRow As Long = 2
  Const CheckColumn As Long = 4 'Column D
  LastRow = Cells(Rows.Count, CheckColumn).End(xlUp).Row
  UnusedColumn = Cells.Find(What:="*", SearchOrder:=xlByColumns, _
                 SearchDirection:=xlPrevious, LookIn:=xlFormulas).Column + 1
  With Cells(StartRow, UnusedColumn).Resize(LastRow - StartRow + 1)
    .FormulaR1C1 = "=IF(RC[-" & (UnusedColumn - 4) & "]<0.1,""X"","""")"
    .Value = .Value
    On Error Resume Next
    .SpecialCells(xlCellTypeConstants).EntireRow.Delete
  End With
End Sub

 

[chadski778]

Thanks guys that's great