Formatting issues with a report

A

amrita17170909

Board Regular
Joined
Dec 11, 2019
Messages
74
Office Version
  1. 2019
  2. 2016
  3. 2013
Platform
  1. Windows
Hi All,

I need help with formatting of a report.

The report takes input from Table 4 and creates an "Attachment A" once the user clicks on the button to create the report.

Table 4 looks as per below:

1. It has columns from A to AA
2. Column A : Customer ID
Column B : ID Description
Column C : Grp
Column D: Prog
Column E: Prog Number
Column F to Column AA : 2020 onwards with the last column for contingency

1578956047113.png



Attachment A should look as per below:

1578956207337.png


The code which I am using at the moment is as per below:

VBA Code: 
Sub generate_report_v_4() ' step 7

Dim IDtag As String
Dim IDdesc As String
Dim LastRowNo As Long
Dim StartIDRow As Long
Dim LastIDRow As Long
Dim IDloop As Long
Dim CurrentTag As String
Dim ID20Years
Dim ID20YearsTot
Dim LbID20Years As Long
Dim UbID20Years As Long
Dim ReportRow As Long

IDtag = ""
IDdesc = ""
StartIDRow = 2
LastIDRow = 0
 
'Calculate the number of rows in Table 4
LastRowNo = Worksheets("Table 4").Cells(Rows.Count, 1).End(xlUp).Row


'Check if there is data in table 4
If LastRowNo < 2 Then
    MsgBox "Sorry, could not find data", vbCritical, ThisWorkbook.Name
    Exit Sub
Else
    If Worksheets("Table 4").Range("A2").Value <> "" Then
        IDtag = Worksheets("Table 4").Range("A2").Value
        CurrentTag = IDtag
        IDdesc = Worksheets("Table 4").Range("B2").Value
    Else
        MsgBox "Sorry, no data", vbCritical, ThisWorkbook.Name
        Exit Sub
    End If
End If

'Code for the format of the report
Call report_aesthetics_1

ReportRow = 6

'write first line
IDtag = Worksheets("Table 4").Cells(StartIDRow, 1).Value
'MsgBox (IDtag)
Worksheets("Attachment A").Cells(ReportRow, 1).Value = IDtag
Worksheets("Attachment A").Cells(ReportRow, 1).Font.Bold = True
Worksheets("Attachment A").Cells(ReportRow, 2).Value = Worksheets("Table 4").Cells(StartIDRow, 2).Value
Worksheets("Attachment A").Cells(ReportRow, 2).Font.Bold = True
Worksheets("Attachment A").Cells(ReportRow, 4).Value = Worksheets("Table 4").Cells(StartIDRow, 4).Value
Worksheets("Attachment A").Cells(ReportRow, 5).Value = Worksheets("Table 4").Cells(StartIDRow, 3).Value
ID20Years = Worksheets("Table 4").Range(Cells(StartIDRow, 6).Address, Cells(StartIDRow, 27).Address).Value
Worksheets("Attachment A").Range(Cells(ReportRow, 6).Address, Cells(ReportRow, 27).Address).Value = ID20Years
ID20YearsTot = ID20Years
LbID20Years = LBound(ID20Years, 2)
UbID20Years = UBound(ID20Years, 2)

'MsgBox (LbID20Years)
'MsgBox (UbID20Years)
'Set for next read
StartIDRow = StartIDRow + 1
CurrentTag = Worksheets("Table 4").Cells(StartIDRow, 1).Value
ReportRow = ReportRow + 1

Do While StartIDRow <= LastRowNo

    Do While IDtag = CurrentTag
        
        Worksheets("Attachment A").Cells(ReportRow, 5).Value = Worksheets("Table 4").Cells(StartIDRow, 3).Value
        Worksheets("Attachment A").Cells(ReportRow, 4).Value = Worksheets("Table 4").Cells(StartIDRow, 4).Value
        ID20Years = Worksheets("Table 4").Range(Cells(StartIDRow, 6).Address, Cells(StartIDRow, 27).Address).Value
        
        'add to total
        For IDloop = LbID20Years To UbID20Years
            ID20YearsTot(1, IDloop) = ID20YearsTot(1, IDloop) + ID20Years(1, IDloop)
        Next IDloop
        
        Worksheets("Attachment A").Range(Cells(ReportRow, 6).Address, Cells(ReportRow, 27).Address).Value = ID20Years
        StartIDRow = StartIDRow + 1
        CurrentTag = Worksheets("Table 4").Cells(StartIDRow, 1).Value
        ReportRow = ReportRow + 1
    Loop
    
    'Finish putting rows and add the total line
    Worksheets("Attachment A").Range(Cells(ReportRow, 5).Address).Value = "TOTAL"
         Worksheets("Attachment A").Range(Cells(ReportRow, 5).Address).Font.Bold = True ' Font should be bold
    Worksheets("Attachment A").Range(Cells(ReportRow, 6).Address, Cells(ReportRow, 27).Address).Value = ID20YearsTot
        Worksheets("Attachment A").Range(Cells(ReportRow, 6).Address, Cells(ReportRow, 27).Address).Font.Bold = True ' Font should be bold 
    
    'If ID20YearsTot < 1 Then ID20YearsTot = "-"
    
    
    ReportRow = ReportRow + 1
    

    'write first line
'    StartIDRow = StartIDRow + 1
    ReportRow = ReportRow + 1
    IDtag = Worksheets("Table 4").Cells(StartIDRow, 1).Value
    Worksheets("Attachment A").Cells(ReportRow, 1).Value = IDtag
    Worksheets("Attachment A").Cells(ReportRow, 1).Font.Bold = True
    'MsgBox (IDtag)
    Worksheets("Attachment A").Cells(ReportRow, 2).Value = Worksheets("Table 4").Cells(StartIDRow, 2).Value
     Worksheets("Attachment A").Cells(ReportRow, 2).Font.Bold = True
    Worksheets("Attachment A").Cells(ReportRow, 5).Value = Worksheets("Table 4").Cells(StartIDRow, 3).Value
    Worksheets("Attachment A").Cells(ReportRow, 4).Value = Worksheets("Table 4").Cells(StartIDRow, 4).Value
    ID20Years = Worksheets("Table 4").Range(Cells(StartIDRow, 6).Address, Cells(StartIDRow, 27).Address).Value
    Worksheets("Attachment A").Range(Cells(ReportRow, 6).Address, Cells(ReportRow, 27).Address).Value = ID20Years
    ID20YearsTot = ID20Years
    LbID20Years = LBound(ID20Years, 2)
    UbID20Years = UBound(ID20Years, 2)
    
    'Set for next read
    StartIDRow = StartIDRow + 1
    CurrentTag = Worksheets("Table 4").Cells(StartIDRow, 1).Value
    ReportRow = ReportRow + 1
    
Loop

'change -values to ()

LastRowNo1 = Worksheets("Attachment A").Cells(Rows.Count, 1).End(xlUp).Row
Worksheets("Attachment A").Range(Cells(2, 6).Address, Cells(LastRowNo1, 27).Address).NumberFormat = "#,##0;(#,##0)"

Call sum_two_columns


End Sub

Code: 
Sub report_aesthetics_1() ' This is used to change the look and feel of Attachment A

    ' No Gridlines for the report
    
    Worksheets("Attachment A").Activate
    ActiveWindow.DisplayGridlines = False
    
    'Add the line "Top of Defence' in the worksheet
    Worksheets("Attachment A").Range("A1:J1").Select
    Selection.Font.Bold = True
    Selection.Font.Size = 12
    
    With Selection
        .HorizontalAlignment = xlCenter
        .VerticalAlignment = xlBottom
        .WrapText = False
        .Orientation = 0
        .AddIndent = False
        .IndentLevel = 0
        .ShrinkToFit = False
        .ReadingOrder = xlContext
        .MergeCells = False
    End With
    Selection.Merge
    Range("A1:J1").Select
    ActiveCell.FormulaR1C1 = "TOP"
  
    ' Add the name of the report "ATTACHMENT A - <Enter Name of Journal>"
    Worksheets("Attachment A").Range("A2:J2").Select
    Selection.Font.Bold = True
    Selection.Font.Size = 16
    Selection.Font.Color = vbRed
    With Selection
        .HorizontalAlignment = xlCenter
        .VerticalAlignment = xlBottom
        .WrapText = False
        .Orientation = 0
        .AddIndent = False
        .IndentLevel = 0
        .ShrinkToFit = False
        .ReadingOrder = xlContext
        .MergeCells = False
    End With
    Selection.Merge
    Range("A2:J2").Select
    ActiveCell.FormulaR1C1 = "ATTACHMENT A "
    
    'Add the month and year of the report
     Worksheets("Attachment A").Range("A3:J3").Select
    Selection.Font.Bold = True
    Selection.Font.Size = 16
        With Selection
        .HorizontalAlignment = xlCenter
        .VerticalAlignment = xlBottom
        .WrapText = False
        .Orientation = 0
        .AddIndent = False
        .IndentLevel = 0
        .ShrinkToFit = False
        .ReadingOrder = xlContext
        .MergeCells = False
    End With
    Selection.Merge
    Range("A3:J3").Select
    ActiveCell.FormulaR1C1 = "<Enter Month and Year of report>"
    
  'Write heading
    Worksheets("Attachment A").Range("A5").Value = "ID"
    Worksheets("Attachment A").Range("B5").Value = "ID Description"
    Worksheets("Attachment A").Range("C5").Value = "Journal Description"
    Worksheets("Attachment A").Range("D5").Value = "Program"
    Worksheets("Attachment A").Range("E5").Value = "Gr"
    Worksheets("Attachment A").Range("F5").Value = "2019-2020"
    Worksheets("Attachment A").Range("G5").Value = "2020-2021"
    Worksheets("Attachment A").Range("H5").Value = "2021-2022"
    Worksheets("Attachment A").Range("I5").Value = "2022-2023"
    Worksheets("Attachment A").Range("J5").Value = "2023-2024"
    Worksheets("Attachment A").Range("K5").Value = "2024-2025"
    Worksheets("Attachment A").Range("L5").Value = "2025-2026"
    Worksheets("Attachment A").Range("M5").Value = "2026-2027"
    Worksheets("Attachment A").Range("N5").Value = "2027-2028"
    Worksheets("Attachment A").Range("O5").Value = "2028-2029"
    Worksheets("Attachment A").Range("P5").Value = "2029-2030"
    Worksheets("Attachment A").Range("Q5").Value = "2030-2031"
    Worksheets("Attachment A").Range("R5").Value = "2031-2032"
    Worksheets("Attachment A").Range("S5").Value = "2032-2033"
    Worksheets("Attachment A").Range("T5").Value = "2033-2034"
    Worksheets("Attachment A").Range("U5").Value = "2034-2035"
    Worksheets("Attachment A").Range("V5").Value = "2035-2036"
    Worksheets("Attachment A").Range("W5").Value = "2036-2037"
    Worksheets("Attachment A").Range("X5").Value = "2037-2038"
    Worksheets("Attachment A").Range("Y5").Value = "2038-2039"
    Worksheets("Attachment A").Range("Z5").Value = "2039-2040"
    Worksheets("Attachment A").Range("AA5").Value = "Contingency"
    Worksheets("Attachment A").Range("AB5").Value = "Total 20 Years (Ex Cont.)"
    Worksheets("Attachment A").Range("AC5").Value = "Total 20 Years (Inc Cont.)"
    
    'Format the headings
    
    'Font should be bold
    
     Range("A5:AC5").Select
    Selection.Font.Bold = True
    Columns("B:B").ColumnWidth = 44.14
    Columns("B:B").ColumnWidth = 49
    With Selection.Interior
        .Pattern = xlSolid
        .PatternColorIndex = xlAutomatic
        .ThemeColor = xlThemeColorDark2
        .TintAndShade = 0
        .PatternTintAndShade = 0
    End With
    
    ' Row height adjustment
    
    Range("A5:AC5").Select
    Selection.RowHeight = 70.5
    Selection.Borders(xlDiagonalDown).LineStyle = xlNone
    Selection.Borders(xlDiagonalUp).LineStyle = xlNone
    With Selection.Borders(xlEdgeLeft)
        .LineStyle = xlContinuous
        .ColorIndex = 0
        .TintAndShade = 0
        .Weight = xlThin
    End With
    With Selection.Borders(xlEdgeTop)
        .LineStyle = xlContinuous
        .ColorIndex = 0
        .TintAndShade = 0
        .Weight = xlThin
    End With
    With Selection.Borders(xlEdgeBottom)
        .LineStyle = xlContinuous
        .ColorIndex = 0
        .TintAndShade = 0
        .Weight = xlThin
    End With
    With Selection.Borders(xlEdgeRight)
        .LineStyle = xlContinuous
        .ColorIndex = 0
        .TintAndShade = 0
        .Weight = xlThin
    End With
    With Selection.Borders(xlInsideVertical)
        .LineStyle = xlContinuous
        .ColorIndex = 0
        .TintAndShade = 0
        .Weight = xlThin
    End With
    With Selection.Borders(xlInsideHorizontal)
        .LineStyle = xlContinuous
        .ColorIndex = 0
        .TintAndShade = 0
        .Weight = xlThin
    End With
    
    'Making sure the headings are in the middle
    
    Range("A5:AC5").Select
    With Selection
        .HorizontalAlignment = xlGeneral
        .VerticalAlignment = xlCenter
        .WrapText = False
        .Orientation = 0
        .AddIndent = False
        .IndentLevel = 0
        .ShrinkToFit = False
        .ReadingOrder = xlContext
        .MergeCells = False
    End With
    
    End Sub


Inspite of trying everything I don't think my program is optimized as it has been hard-coded and also very long as I have used macros to understand how I can do stuff. I am also not able to include the following things in my code:
1. Every ID in the final report needs to have a box around it so it comes across as one entity.
2. The report should show all "0"'s in the report as "-"
3. I need to include a validation rule in which if the Total is not 0 it should change the font color to red .

Thanks for help in advance.
 

Excel Facts

Excel Joke
Why can't spreadsheets drive cars? They crash too often!
Sort by date Sort by votes
Here's my attempt. Not sure what formulas you've got with regards to total etc. so I made it up.

Book1
ABCDEFGHIJKLMNOPQRSTUVWXYZAAABAC
3IDID DescriptionJournal DescriptionProgGrp2019-202020-212021-222022-232023-242024-252025-262026-272027-282028-292029-302030-312031-322032-332033-342034-352035-362036-372037-382038-392039-40Not sure what this saysNot sure what this saysNot sure what this says
4123AbcdFFAb-----11121111(21,868,000)11111111111111-(21,867,824)(21,867,824)
5FFAbcd---(123)3456582135454332,1322,1322,131213,2131331,2132131332311333252,952252,952
6FFAbcd---(123)3456582135454332,1322,1322,131213,2131331,213213133231133-252,949252,949
7AAAbcd--------1233456582135454332,1322,1322,131213,2131331,21321313253,116253,116
8AAAbcd-----11(12)(11)--------------(12)(12)
9TOTAL---(246)6901,3384261081,220(21,803,391)5,0334,486426,48181034,5592,5592,158213,2781961,24022016
10
11145EfghBBxy14525243521111----------------451451
12CCee14525243521111----------------451451
13BBee14525243521111----------------451451
14TOTAL435757210563333----------------
15
Attachment A
Cell Formulas
RangeFormula
AB4:AC8, AB11:AC13AB4=SUM($F4:$AA4)
F9:AA9F9=SUM(F4:F8)
F14:AA14F14=SUM(F11:F13)


VBA Code: 
Option Explicit

Sub generate_report_v_4() ' step 7

    Dim LastRow As Long, ctr As Long, fSumRow As Long, lSumRow As Long
    Dim SwapAry As Variant
    Dim cCel As Range
  
    With Application
        .ScreenUpdating = False
        .DisplayAlerts = False
    End With
  
    If SheetExists("Attachment A") Then
        Sheets("Attachment A").Delete
    End If
  
    Sheets.Add(After:=Sheets(Sheets.Count)).Name = "Attachment A"
  
    With Sheets("Table 4")
        LastRow = .Cells(.Rows.Count, 1).End(xlUp).Row
      
        .Range("A3:AA" & LastRow).Copy _
            Destination:=Sheets("Attachment A").Range("A3")
    End With
  
    With Sheets("Attachment A")
        LastRow = .Cells(.Rows.Count, 1).End(xlUp).Row
  
        .Columns("C").EntireColumn.Insert _
            Shift:=xlShiftToRight
          
        .Columns("F").EntireColumn.Delete _
            Shift:=xlShiftToLeft
          
        SwapAry = .Range("D3:D" & LastRow).Value
      
        .Range("C3").Value = "Journal Description"
        .Range("D3:D" & LastRow).Value = .Range("E3:E" & LastRow).Value
        .Range("E3:E" & LastRow).Value = SwapAry
        .Range("AA3").Value = "Not sure what this says"
        .Range("AB3").Value = "Not sure what this says"
        .Range("AC3").Value = "Not sure what this says"
      
        For Each cCel In .Range("F3:Z3")
            cCel.Value = cCel.Value - 1 & "-" & Right(cCel.Value, 2)
        Next cCel
      
        .Range("E" & LastRow).Offset(1).Value = UCase("total")
      
        For ctr = LastRow To 5 Step -1
            If .Range("A" & ctr).Value <> .Range("A" & ctr).Offset(-1).Value Then
                .Range(ctr & ":" & ctr + 1).EntireRow.Insert _
                    Shift:=xlShiftDown
                  
                .Range("E" & ctr).Value = UCase("total")
            End If
        Next ctr
      
        LastRow = .Cells(.Rows.Count, 1).End(xlUp).Row
      
        fSumRow = 4
      
        While lSumRow < LastRow
            lSumRow = .Range("A" & fSumRow).End(xlDown).Row
          
            .Range("F" & lSumRow + 1 & ":AA" & lSumRow + 1).Formula = "=SUM(F" & fSumRow & ":F" & lSumRow & ")"
          
            For ctr = fSumRow To lSumRow
                .Range("AB" & ctr & ":AC" & ctr).Formula = "=SUM($F" & ctr & ":$AA" & ctr & ")"
            Next ctr

            fSumRow = lSumRow + 3
        Wend
    End With
  
    Call report_aesthetics_1
  
    With Application
        .ScreenUpdating = True
        .DisplayAlerts = True
    End With

End Sub

Sub report_aesthetics_1() ' This is used to change the look and feel of Attachment A

    Dim LastRow As Long, fRow As Long, lRow As Long
  
    With Application
        .ScreenUpdating = False
        .DisplayAlerts = False
    End With

    With Sheets("Attachment A")
        LastRow = .Cells(.Rows.Count, 1).End(xlUp).Row
  
        .Cells.Font.Size = 8
  
        With .Rows(3)
            .RowHeight = 60
            .VerticalAlignment = xlCenter
            .Font.Bold = True
        End With
      
        .Columns.AutoFit
      
        With .Range("A3:AC3")
            .Interior.Color = RGB(240, 240, 240)
            .Borders.LineStyle = xlContinuous
            .HorizontalAlignment = xlCenter
            .WrapText = True
        End With
      
        With .Range("A:A, D:AC")
            .EntireColumn.ColumnWidth = 9
          
        End With
      
        fRow = 4
      
        While lRow < LastRow
            lRow = .Range("A" & fRow).End(xlDown).Row
          
            With .Range("A" & fRow & ":AC" & lRow)
                .Borders.LineStyle = xlContinuous
                .NumberFormat = "#,##0;(#,##0);-"
            End With
          
            .Range("AB" & fRow & ":AC" & lRow).Font.Bold = True
          
            With .Rows(lRow + 1)
                .Font.Bold = True
                .NumberFormat = "#,##0;(#,##0);-"
            End With
          
            With .Range("A" & fRow & ":A" & lRow)
                .Merge
                .HorizontalAlignment = xlCenter
                .VerticalAlignment = xlCenter
            End With
          
            With .Range("B" & fRow & ":B" & lRow)
                .Merge
                .HorizontalAlignment = xlCenter
                .VerticalAlignment = xlCenter
            End With
          
            With .Range("C" & fRow & ":C" & lRow)
                .Merge
                .HorizontalAlignment = xlCenter
                .VerticalAlignment = xlCenter
            End With
          
          
            fRow = lRow + 3
        Wend
    End With
  
    With Application
        .ScreenUpdating = True
        .DisplayAlerts = True
    End With

End Sub

Function SheetExists(Sh As String) As Boolean

    Dim wkSheet As Worksheet
  
    On Error Resume Next
    Set wkSheet = Worksheets(Sh)
    On Error GoTo 0
  
    If Not wkSheet Is Nothing Then SheetExists = True

End Function
Table 4.JPG
Attachment A.JPG
 
Last edited:
Upvote 0
Thanks so much for your response.

When I run the code it is giving me the below error:

1578976025484.png


And when I click on debug it is highlighting the below line:

.Range("F" & lSumRow + 1 & ":AA" & lSumRow + 1).Formula = "=SUM(F" & fSumRow & ":F" & lSumRow & ")"

Are you able to give some guidance ?
 
Upvote 0
amrita17170909 said:
Thanks so much for your response.

When I run the code it is giving me the below error:

View attachment 3900

And when I click on debug it is highlighting the below line:

.Range("F" & lSumRow + 1 & ":AA" & lSumRow + 1).Formula = "=SUM(F" & fSumRow & ":F" & lSumRow & ")"

Are you able to give some guidance ?
Click to expand...

I'm not getting that error here.

Here's my file...

Report.xlsm
 
Upvote 0
Thanks for your help. I am just trying to work it out at my end.

Would you be able to advise what this line of code is doing ?

VBA Code: 
For Each cCel In .Range("F3:Z3")
            cCel.Value = cCel.Value - 1 & "-" & Right(cCel.Value, 2)
        Next cCel
 
Upvote 0
Thanks for your help so far:

I had a few questions for you:
1. I will show you the test data which I am using to run the above program and the output which am getting

Test Data
1579043392933.png


Output:
1579043438244.png


What I need :

1579046047823.png
 
Upvote 0
Hi Judaa,

I am bombarding you with information but I think I realised what the problem is :

1. The information in "Table 4" which is copied across to "Attachment A" has a line at the end Grand Total which should not be included in Attachment A.

2. Also if we add the report headers to the report e.g Journal description etc. I added it as per below and the program adds "Total" to line.

I think because of the above two things I am getting the error I am getting .

I have copied the snapshots below :

1579061211304.png

1579061269408.png
 
Upvote 0
Hi, sorry for the delay.

I wrote the code based on the sample you gave in your first post.
  1. Table 4 started on Row 3 (It now starts on Row 1)
  2. Attachment A started on Row 3 (It now starts on Row 5)
  3. The headers were in the format 2020, 2021.... (They now say Sum of 2020, Sum of 2021....)
  4. There are now extra rows that you don't want included in the final output
That's the reasons you're seeing errors when running the code on your file as opposed to the sample I made to test the code.

VBA Code: 
For Each cCel In .Range("F3:Z3")
    cCel.Value = cCel.Value - 1 & "-" & Right(cCel.Value, 2)
Next cCel
This code loops over the header row and changes it from 2020 format to 2019-20 format

In your new sample this would have to be changed for something like...
VBA Code: 
For Each cCel In .Range("F5:Z5")
    cCel.Value = CInt(Right(cCel.Value, 4)) - 1 & "-" & Right(cCel.Value, 2)
Next cCel
 
Upvote 0
Hey Juddaaaa,

Thanks so much for you guidance.

Any chance how can I get rid of the "total" text in the odd lines ?

Thanks,

Amrita
 
Upvote 0
I have made the following changes to the code considering the changes:
1. Table 4 started on Row 3 (It now starts on Row 1) and has to be copied to Attachment A at starting row 5
VBA Code: 
With Sheets("Table 4")
        LastRow = .Cells(.Rows.Count, 1).End(xlUp).Row
     
        .Range("A1:AA" & LastRow).copy _
            Destination:=Sheets("Attachment A").Range("A7") 'copy the table 4 in Attachment A
    End With

2. Attachment A started on Row 3 (It now starts on Row 5) : The headers for Attachment A have to be in Row 5 and the actual values have to start from row 7

With Sheets("Attachment A")
LastRow = .Cells(.Rows.Count, 1).End(xlUp).Row

.Columns("C").EntireColumn.Insert _
Shift:=xlShiftToRight

.Columns("F").EntireColumn.Delete _
Shift:=xlShiftToLeft

SwapAry = .Range("D3:D" & LastRow).Value

.Range("C5").Value = "Journal Description"
.Range("D5:D" & LastRow).Value = .Range("E5:E" & LastRow).Value
.Range("E5:E" & LastRow).Value = SwapAry
.Range("AA5").Value = "Not sure what this says"
.Range("AB5").Value = "Not sure what this says"
.Range("AC5").Value = "Not sure what this says"

For Each cCel In .Range("F5:Z5")
cCel.Value = CInt(Right(cCel.Value, 4)) - 1 & "-" & Right(cCel.Value, 2)
Next cCel


As soon as I make the above changes I get an error in this porting of the code :

1579129871096.png
 
Upvote 0
You must log in or register to reply here.

Similar threads

L
  • Locked
  • Question
Help Cleaning Up Code
Replies
2
Views
333
RoryA
RoryA
S
  • Question
CSV export to remove column
Replies
1
Views
98
StellarRumble59
S
larinda4
  • Question
VBA: Send Outlook Email & Attach PDF
Replies
1
Views
137
Trebor76
T
J
  • Solved
Vba timestamp when pressing a button
Replies
4
Views
139
rollis13
rollis13
K
  • Solved
help with 'no cells found' error... (ideas on how to get around this...)
Replies
3
Views
188
Alex Blakenburg
A

Forum statistics

Threads
1,215,028
Messages
6,122,753
Members
449,094
Latest member
dsharae57

Share this page

We've detected that you are using an adblocker.

We have a great community of people providing Excel help here, but the hosting costs are enormous. You can help keep this site running by allowing ads on MrExcel.com.
Allow Ads at MrExcel

Which adblocker are you using?

Disable AdBlock

Follow these easy steps to disable AdBlock

1)Click on the icon in the browser’s toolbar.
2)Click on the icon in the browser’s toolbar.
2)Click on the "Pause on this site" option.
Go back

Disable AdBlock Plus

Follow these easy steps to disable AdBlock Plus

1)Click on the icon in the browser’s toolbar.
2)Click on the toggle to disable it for "mrexcel.com".
Go back

Disable uBlock Origin

Follow these easy steps to disable uBlock Origin

1)Click on the icon in the browser’s toolbar.
2)Click on the "Power" button.
3)Click on the "Refresh" button.
Go back

Disable uBlock

Follow these easy steps to disable uBlock

1)Click on the icon in the browser’s toolbar.
2)Click on the "Power" button.
3)Click on the "Refresh" button.
Go back
Back
Top