Formula to Count Unique ID numbers per month

[Tmoske]

I need to count how many unique ID numbers there are per month.I have figured out how to count the unique ID's for the first month (Jan) but after that I'm having trouble trying to get the count right for Feb and Mar. Formula I used in cell E2 is:
{=SUM(IF($A$2:$A$14<=DATE(2013,1,31),1/(COUNTIFS(A2:A14,"<="&DATE(2013,1,31),B2:B14,B2:B14)),0))}


-- removed inline image ---


Thanks,
Tmoske

 

[Tmoske]

Sorry, the image of my spreadsheet did not stay when I hi submit thread. How do I post my table?

 

[shyy]

How does your data look like? For the month is it simple June or 6/1/2014 etc..

 

[Tmoske]

Dates are written out like 6/1/2014

 

[Marcelo Branco]

Maybe something like this (dates as dd/mm/yyyy)

	A​	B​	C​	D​	E​	F​
1​	Date​	ID​		Month​	Year​	Unique​
2​	25/01/2014​	ID1​		1​	2014​	4​
3​	26/01/2014​	ID2​		2​	2014​	2​
4​	27/01/2014​	ID3​
5​	28/01/2014​	ID4​
6​	29/01/2014​	ID2​
7​	30/01/2014​	ID1​
8​	31/01/2014​	ID3​
9​	01/02/2014​	ID1​
10​	02/02/2014​	ID4​
11​	03/02/2014​	ID1​
12​	04/02/2014​	ID4​
13​	05/02/2014​	ID4​
14​	06/02/2014​	ID4​

Array formula in F2 copied down
=SUM(IF(FREQUENCY(IF($A$2:$A$14<>"",IF(MONTH($A$2:$A$14)=D2,IF(YEAR($A$2:$A$14)=E2,MATCH($B$2:$B$14,$B$2:$B$14,0)))),ROW($B$2:$B$14)-ROW($B$2)+1),1))

confirmed with Ctrl+Shift+Enter

M.

 

[Tmoske]

If it matters my ID numbers are alpha numeric. Example BAF13033M01.

 

[Tmoske]

Marcelo,
Thanks so much, the formula seems to work exactly the way that I needed.

-Tmoske

 

[Marcelo Branco]

Marcelo,
Thanks so much, the formula seems to work exactly the way that I needed.

-Tmoske

You are welcome. Glad for helping

M.