From column to matrix

[ezequiel]

Hi everyone,

Does someone know any macro that can let me change a column with a ton of cells into a matrix m x n?

I badly need this since I have a lot of cells in the column and the matrix has to be 356 x 94 !

Thanks a lot

 

[JackDanIce]

Welcome to the board.

Assuming your data is in column A, the code below will copy 356 rows and paste into column B and then onwards until the last row in column A. You'll probably need to adjust settings to fit your own requirements

Try:

Sub IncestousTurtles()
Dim i As Long, r As Long, c As Long
Application.ScreenUpdating = False
r = 356
c = 2
For i = 1 To Range("A" & Rows.Count).End(xlUp).row Step 356
    Range(Cells(i, 1), Cells(i + 355, 1)).Copy
    Cells(1, c).PasteSpecial Paste:=xlValues
    c = c + 1
Next i
Application.ScreenUpdating = True
End Sub

 

[mirabeau]

hi,

original col data in column A, matrix printout from cell C1 on and down, or can be used under name matr in any further use.

Sub coltomatrix()
Dim a As Variant, matr(), r As Long, s As Long
Dim i As Long, j As Long, k As Long
r = 356
s = 94
a = Range("A:A")
ReDim matr(1 To r, 1 To s)
For j = 1 To s
    For i = 1 To r
        k = k + 1
        matr(i, j) = a(k, 1)
Next i, j
Range("C1").Resize(r, s) = matr
End Sub