Go down a cell until it finds a grey colored cell

[Doblon]

Hi I need help with programing a macros to go down a cell until it finds a grey colored cell. Is it possible?

So far i have the following:

Sub AlimentaciónPanelLegacy()
Dim LC As Long
Dim RC As Long
Sheets("Action Items").Select
Range("C1").Select

Do Until ActiveCell.Value = GREY COLORED CELL
ActiveCell.Offset(1, 0).Select
Loop

Range("A1").Select
End Sub

Many thanks!

 

[MrKowz]

Not sure what shade of grey you are using... try:

Sub GreyRow()
Dim LR As Long, i As Long
LR = Sheets("Action Items").Range("C" & Rows.Count).End(xlUp).Row
For i = 1 To LR
   If Sheets("Action Items").Range("C" & i).Interior.ColorIndex = 15 Then
      Sheets("Action Items").Range("C" & i).Select
   End If
Next i
End Sub

If that doesn't work, change the ColorIndex = 15 to 48 or 16.

 

[SteveO59L]

But, your code doesnt actually do anything!

 

[VoG]

Try like this - you might need to change the 56 to match the shade of grey

Sub AlimentaciónPanelLegacy()
Dim r As Range
Sheets("Action Items").Select
Set r = Range("C1")

Do Until r.Interior.ColorIndex = 56
    Set r = r.Offset(1)
Loop

r.Select
End Sub

 

[Simon Lloyd]

Like this (depending on what colour grey you used!)

Sub d()
Dim MyCell As Range
'this next line only works if there is a value in the cell too, if this
'is not the case then hard code the range like this Range("C1:C100")
For Each MyCell In Range("C1:C" & Range("C" & Rows.Count).End(xlUp).Row)
If MyCell.Interior.ColorIndex = 48 Then
MsgBox MyCell.Address & " is Grey"
End If
Next MyCell
End Sub

 

[Doblon]

thank you to all!

 

[Simon Lloyd]

If i was you i'd go with Vog's code, short, to the point and doesnt rely on the cell containing a value, although i wouldnt Select the sheet i'd use a With!