Have data in "pivot format", what to transform it into "rows format"

[OldManExcellor]

I have data in Excel presented in what I would call "pivot format":

I want to transform that data into what I would call "rows format"

(so that I can later use it in pivot tables)

The data file I have is quite large. What is a fast and efficient way to transform the data from "pivot" to "rows" using either excel or access?

 

[OldManExcellor]

The solution doesn't have to be fast and efficient. Any solution that I can use would be great.

 

[Weaver]

This vb code ought to help.

It creates the new layout on a fresh tab

You should run it when on the tab with the original data. This data should appear as in your image, IE, row heads in column A and column heads in row 1

Sub convertLayout()
    Dim src, dst, dr, r, c
    Application.ScreenUpdating = False
    Set src = ActiveSheet
    Set dst = Sheets.Add(after:=src)
    dr = 2
    With src
        lr = .Cells(Rows.Count, "A").End(xlUp).Row
        lc = .Cells(1, Columns.Count).End(xlToLeft).Column
    End With
    With dst
        For r = 2 To lr
            For c = 2 To lc
                .Cells(dr, 1) = src.Cells(r, "A")
                .Cells(dr, 2) = src.Cells(1, c)
                .Cells(dr, 3) = src.Cells(r, c)
                dr = dr + 1
            Next c
        Next r
        With .Range("A1:C1")
            .Value = Array("Row Head", "Column Head", "Value")
            .EntireColumn.AutoFit
        End With
    End With
End Sub