How can I create a code to calculate first day in the month taking bank holidays away?

[Eric Penfold]

Using code below as basis?

Option Explicit

Sub FillDates()

Dim wb As Workbook
Dim ws As Worksheet
Dim FCell As Range
Dim LCell As Range
Dim LRow   As Long

Set wb = Workbooks("DailyMail.xlsx")
Set ws = wb.Worksheets("Daily Mail Update")
Set FCell = ws.Range("A2")
Set LCell = ws.Range("A2" & LRow)
LRow = ws.Cells(Rows.Count, 1).End(xlUp).Row

If Not Date = Application.WorkDay(DateSerial(Year(Date), Month(Date), 0), 1) Or _
    Date = Application.WorkDay(DateSerial(Year(Date), Month(Date), 0), 2) Then
    
FCell.Clear

FCell = Evaluate("Workday(EOMonth(Now(),-1),1)")
   
With FCell
    .HorizontalAlignment = xlCenter
    .NumberFormat = ("dd/mm/yy")
End With

End If

End Sub

 

[bobsan42]

First, there is a function that does that, do you insist on code?
Second, you will need a list of dates for the holidays.

 

[Eric Penfold]

First, there is a function that does that, do you insist on code?
Second, you will need a list of dates for the holidays.

It`s all part of a bigger VBA so like to keep it as is.

 

[bobsan42]

You still need a list with the holidays dates.

 

[Eric Penfold]

You still need a list with the holidays dates.

Ok thanks

 

[bobsan42]

Assuming:

• you want to fill all non-empty cells in column A with the first working day of the current month
• you have a list of dates with the Bank Holidays in BH1:BH10 for example (you can change this in the code)

Try this:

Sub FillDates()
    Dim wb As Workbook
    Dim ws As Worksheet
    Dim FCell As Range
    Dim LRow   As Long

    Set wb = ActiveWorkbook ' Workbooks("DailyMail.xlsx")
    Set ws = ActiveSheet 'wb.Worksheets("Daily Mail Update")
    LRow = ws.Cells(Rows.Count, 1).End(xlUp).Row
    Set FCell = ws.Range("A2:A" & LRow)
    With FCell
        .Value = FirstWorkDayOfMonth(Date, ws.Range("BH1:BH10"))
        .HorizontalAlignment = xlCenter
        .NumberFormat = ("dd/mm/yy")
    End With
    Set wb = Nothing
    Set ws = Nothing
    Set FCell = Nothing
End Sub

Function FirstWorkDayOfMonth(ByVal xDate As Date, Optional ByRef BankHolidays As Range) As Date
    With Application.WorksheetFunction
        FirstWorkDayOfMonth = .WorkDay(.EoMonth(xDate, -1), 1, BankHolidays)
    End With
End Function

There is another function you can use WorkDay_Intl - it allows some control on the weekend days.

 

[bobsan42]

Assuming:

• you have Dates in the non-empty cells in column A, but you want to replace them with the first working day of their month
• you have a list of dates with the Bank Holidays in BH1:BH10 for example (you can change this in the code)

Try this:

Sub FillDates2()
    Dim wb As Workbook
    Dim ws As Worksheet
    Dim FCell As Range, cc As Range
    Dim LRow   As Long, x As Date
    Dim bhRange As Range

    Set wb = ActiveWorkbook ' Workbooks("DailyMail.xlsx")
    Set ws = ActiveSheet 'wb.Worksheets("Daily Mail Update")
    LRow = ws.Cells(Rows.Count, 1).End(xlUp).Row
    Set FCell = ws.Range("A2:A" & LRow)
    Set bhRange = ws.Range("BH1:BH10")
    
    For Each cc In FCell.Cells
        If Not IsDate(cc.Value) Then
            cc.Clear
        Else
            x = cc.Value
            cc.Value = FirstWorkDayOfMonth(Date, bhRange)
            cc.HorizontalAlignment = xlCenter
            cc.NumberFormat = ("dd/mm/yy")
        End If
    Next cc
    Set wb = Nothing
    Set ws = Nothing
    Set FCell = Nothing
    Set cc = Nothing
    Set bhRange = Nothing
End Sub

Function FirstWorkDayOfMonth(ByVal xDate As Date, Optional ByRef BankHolidays As Range) As Date
    With Application.WorksheetFunction
        FirstWorkDayOfMonth = .WorkDay(.EoMonth(xDate, -1), 1, BankHolidays)
    End With
End Function

 

[Eric Penfold]

Thank u works a Dream