HOW DO I ARRANGE IN EXCEL

[peterappiahkubi]

KINDLY ASSIST ME WITH A FORMULA TO ARRANGE IN ORDER ACCORDING TO THEIR POSITIONS SO THAT THE STUDENT WITH THE 1ST POSITION COMES FIRST, FOLLOWED BY THE 2ND, THEN 3RD, 4TH ..... IN THAT ORDER IN EXCEL USING THE IMAGE ATTARCHED

 

[Dave Patton]

Did you try the sort function?

N.B. This site has a tool called XL2BB (Excel to Bulletin Board); it allows you to put an extract of your worksheet into your post. It allows the volunteer helpers to copy your data directly without having to manually retype everything from a picture. You're likely to get faster/better answers if you use it.

Instructions on using this tool can be found here: XL2BB Add-in

 

[johnnyL]

Did you try the sort function?

Sort function was introduced in Excel 365

 

[johnnyL]

Here is the XL2BB ...

Book1
	A	B	C	D
1	S/N	NAME	TOTAL MARKS	POSITION
2	1	APPIAH DWAAH JESUS	609	4TH
3	2	APPIAH OSEI KWAME	510	9TH
4	3	ASAMOAH JOSIAH FRIMPONG	586	7TH
5	4	COBBINAH PHILIP	615	3RD
6	5	KANKAM KINGSLEY	625	1ST
7	6	LEH KOJO RAYMOND	577	8TH
8	7	OPPONG BLESSING	507	10TH
9	8	OWUSU LUCKY	618	2ND
10	9	PABLO NELSON	600	6TH
11	10	YEBOAH KWAKU JONATHON	609	4TH
Sheet1

 

[navic]

You can try
Add an auxiliary column to the original data (you can hide this column)

Formula in the 'E2' cell

=LOOKUP(99^99,--(0&MID(D2,MIN(FIND({0,1,2,3,4,5,6,7,8,9},D2&1234567890)),ROW(INDIRECT("1:"&LEN(D2)+1)))))

Results:

The formula in the 'G2' cell

=INDEX($A$2:$A$11,MATCH(H2,$D$2:$D$11,0))

The formula in the 'H2' cell

=IF(SMALL($E$2:$E$100,ROW()-1)=1,SMALL($E$2:$E$100,ROW()-1)&"st",IF(SMALL($E$2:$E$100,ROW()-1)=2,SMALL($E$2:$E$100,ROW()-1)&"nd",IF(SMALL($E$2:$E$100,ROW()-1)=3,SMALL($E$2:$E$100,ROW()-1)&"rd",IF(SMALL($E$2:$E$100,ROW()-1)>=4,SMALL($E$2:$E$100,ROW()-1)&"th",""))))

The formula in the 'I2' cell (copy to the 'J' column)

=VLOOKUP($G2,$A$2:$C$11,COLUMN(B$1),FALSE)

 

[Fluff]

How about

+Fluff 1.xlsm
	A	B	C	D	E	F	G	H	I	J
1	S/N	NAME	TOTAL MARKS	POSITION			S/N	NAME	TOTAL MARKS	POSITION
2	1	APPIAH DWAAH JESUS	609	4TH		625	5	KANKAM KINGSLEY	625	1ST
3	2	APPIAH OSEI KWAME	510	9TH		618	8	OWUSU LUCKY	618	2ND
4	3	ASAMOAH JOSIAH FRIMPONG	586	7TH		615	4	COBBINAH PHILIP	615	3RD
5	4	COBBINAH PHILIP	615	3RD		609	1	APPIAH DWAAH JESUS	609	4TH
6	5	KANKAM KINGSLEY	625	1ST		609	10	YEBOAH KWAKU JONATHON	609	4TH
7	6	LEH KOJO RAYMOND	577	8TH		600	9	PABLO NELSON	600	6TH
8	7	OPPONG BLESSING	507	10TH		586	3	ASAMOAH JOSIAH FRIMPONG	586	7TH
9	8	OWUSU LUCKY	618	2ND		577	6	LEH KOJO RAYMOND	577	8TH
10	9	PABLO NELSON	600	6TH		510	2	APPIAH OSEI KWAME	510	9TH
11	10	YEBOAH KWAKU JONATHON	609	4TH		507	7	OPPONG BLESSING	507	10TH
Lists

Cell Formulas
Range	Formula
F2:F11	F2	=LARGE($C$2:$C$11,ROWS(F$2:F2))
G2:J11	G2	=INDEX(A$2:A$11,AGGREGATE(15,6,(ROW($C$2:$C$11)-ROW($C$2)+1)/($C$2:$C$11=$F2),COUNTIFS($F$2:$F2,$F2)))

 

[peterappiahkubi]

How about
i got it. thanks soo much

 

[Fluff]

Glad we could help & thanks for the feedback.

 

[Dave Patton]

Re Post #2. I said sort function meaning the built in functionality - Data Sort on Total Marks Largest of smallest

Aggregate_a.xlsm
	A	B	C	D
1	S/N	NAME	TOTAL MARKS	POSITION
2	5	KANKAM KINGSLEY	625	1ST
3	8	OWUSU LUCKY	618	2ND
4	4	COBBINAH PHILIP	615	3RD
5	1	APPIAH DWAAH JESUS	609	4TH
6	10	YEBOAH KWAKU JONATHON	609	4TH
7	9	PABLO NELSON	600	6TH
8	3	ASAMOAH JOSIAH FRIMPONG	586	7TH
9	6	LEH KOJO RAYMOND	577	8TH
10	2	APPIAH OSEI KWAME	510	9TH
11	7	OPPONG BLESSING	507	10TH
3c