how populate items in multiple comboboxes and textboxes without selection

[Mussa]

hi
I have many comboboxes(1,2,3,4) link with COL A,B,C,D and textboxes (1,2,3) link with COL E,F,G . so what I want when select combobox1 should filled the others comboboexs and textboxes based on data in sheet1 as in the pictures .
first when select item in combobox1

expected result fill the others comboboxes and textboxes

 

[Mussa]

bump

 

[Akuini]

Could you upload a sample workbook (without sensitive data) to a sharing site like dropbox.com or google drive?
And then share the link here.
This will make it easier to test & find a solution.

 

[Mussa]

thanks
this is the file combobox.xlsm

 

[Akuini]

Try this:
I assume col "BATCH" has unique values.

Private Sub UserForm_Initialize()
With Sheets("Sheet1")
    With .Range("A2", .Cells(.Rows.Count, "A").End(xlUp))
        ComboBox1.List = .Value
        ComboBox2.List = .Offset(, 1).Value
        ComboBox3.List = .Offset(, 2).Value
        ComboBox4.List = .Offset(, 3).Value
    End With
End With

End Sub

Private Sub ComboBox1_Change()
Dim c As Range
With Sheets("Sheet1")
   
    Set c = .Range("A:A").Find(What:=ComboBox1.Value, LookIn:=xlValues, LookAt:=xlWhole, SearchOrder:=xlByRows, _
    SearchDirection:=xlNext, MatchCase:=False, SearchFormat:=False)
    If Not c Is Nothing Then
        ComboBox2.Value = c.Offset(, 1).Value
        ComboBox3.Value = c.Offset(, 2).Value
        ComboBox4.Value = c.Offset(, 3).Value
        TextBox1.Value = c.Offset(, 4).Value
        TextBoxPrice.Value = c.Offset(, 5).Value
        TextBoxTotal.Value = c.Offset(, 6).Value
    End If
End With
End Sub

 

[Mussa]

magificiant ! you've answered my question . curiosity if I add multiple comboboxes and textboxes withe same structure. I see your code and I can add it but the code becomes more long . if there is way to make short will be greate . like this

With .Range("A2", .Cells(.Rows.Count, "A").End(xlUp))
        ComboBox1.List = .Value
        ComboBox2.List = .Offset(, 1).Value
        ComboBox3.List = .Offset(, 2).Value
        ComboBox4.List = .Offset(, 3).Value
        ComboBox5.List = .Value
        ComboBox6.List = .Offset(, 1).Value
        ComboBox7.List = .Offset(, 2).Value
        ComboBox8.List = .Offset(, 3).Value
        ComboBox9.List = .Value
        ComboBox10.List = .Offset(, 1).Value
        ComboBox11.List = .Offset(, 2).Value
        ComboBox12.List = .Offset(, 3).Value
    End With

and

If Not c Is Nothing Then
        ComboBox2.Value = c.Offset(, 1).Value
        ComboBox3.Value = c.Offset(, 2).Value
        ComboBox4.Value = c.Offset(, 3).Value
        TextBox1.Value = c.Offset(, 4).Value
        TextBoxPrice.Value = c.Offset(, 5).Value
        TextBoxTotal.Value = c.Offset(, 6).Value
        
        ComboBox6.Value = c.Offset(, 1).Value
        ComboBox7.Value = c.Offset(, 2).Value
        ComboBox8.Value = c.Offset(, 3).Value
        TextBox4.Value = c.Offset(, 4).Value
        TextBoxPrice1.Value = c.Offset(, 5).Value
        TextBoxTotal1.Value = c.Offset(, 6).Value
        ComboBox10.Value = c.Offset(, 1).Value
        ComboBox11.Value = c.Offset(, 2).Value
        ComboBox12.Value = c.Offset(, 3).Value
        TextBox7.Value = c.Offset(, 4).Value
        TextBoxPrice2.Value = c.Offset(, 5).Value
        TextBoxTotal2.Value = c.Offset(, 6).Value
        
    End If

if this is not clear I will attach pic

 

[Akuini]

For the first example, try:

With .Range("A2", .Cells(.Rows.Count, "A").End(xlUp))
        For i = 1 To 4
            Me.Controls("ComboBox" & i) = .Offset(, i - 1).Value
            Me.Controls("ComboBox" & i + 4) = .Offset(, i - 1).Value
            Me.Controls("ComboBox" & i + 8) = .Offset(, i - 1).Value
        Next
End With

 

[Mussa]

thanks for your cooperation . it gives error
so I attach file and check combobox-change how mod
thanks again
combobox2.xlsm

 

[Akuini]

Sorry, try this one:

Private Sub UserForm_Initialize()
With Sheets("Sheet1")
    With .Range("A2", .Cells(.Rows.Count, "A").End(xlUp))
        For i = 1 To 4
            Me.Controls("ComboBox" & i).List = .Offset(, i - 1).Value
            Me.Controls("ComboBox" & i + 4).List = .Offset(, i - 1).Value
            Me.Controls("ComboBox" & i + 8).List = .Offset(, i - 1).Value
        Next
    End With
End With

End Sub

but you need to place the comboboxes in correct order.

 

[Mussa]

wow ! your super great !
thanks so much