How To Extract Values Based On Criteria In Excel

[matthewbutterworth]

Hi, my brain has turned to blancmange attempting to solve this one on my own. Help is needed, please.

I'm trying to return the column values of rows that have a certain value. I've got close with this. https://www.extendoffice.com/documents/excel/3367-excel-extract-row-that-meet-criteria.html

This is an approximation of my main data sheet.

	A	B	C	D	E	F	G	H	I
1	(The top row is used)
2	SOURCE			DATE	MESSAGE	URL
3	twitter			01/11/2017	Message a	www.a.com
4	facebook			02/11/2017	Message b	www.b.com
5	linkedin			03/11/2017	Message c	www.c.com
6	twitter			04/11/2017	Message d	www.d.com
7	twitter			05/11/2017	Message e	www.e.com
8

<tbody>
</tbody>

And this what I would like to return in a separate sheet. In the example below, this is the data that relates to twitter. I would like to hardcode IF=twitter in the formula, rather than referencing a cell. I'll then create separate sheets for linkedin and facebook.

	A	B	C	D	E	F	G	H	I
1	01/11/2017	Message a	www.a.com
2	04/11/2017	Message d	www.d.com
3	05/11/2017	Message e	www.e.com
4
5
6
7
8

<tbody>
</tbody>

Hopefully this explains it well enough for you to understand.

Thank you Forum! Matt.

 

[Momentman]

I would use a formula like this, entered with CTRL+SHIFT+ENTER

this can also be solved using "ADVANCED FILTER"

But here,,

Excel 2010
	A	B	C	D	E	F
1	(The top row is used)
2	SOURCE			DATE	MESSAGE	URL
3	twitter			01/11/2017	Message a	www.a.com
4	facebook			02/11/2017	Message b	www.b.com
5	linkedin			03/11/2017	Message c	www.c.com
6	twitter			04/11/2017	Message d	www.d.com
7	twitter			05/11/2017	Message e	www.e.com
8
9
10	01-Nov-17	Message a	www.a.com
11	04-Nov-17	Message d	www.d.com
12	05-Nov-17	Message e	www.e.com
Sheet4

Cell Formulas
Range	Formula
A10	{=IFERROR(INDEX(D$3:D$7,SMALL(IF($A$3:$A$7="Twitter",ROW($A$3:$A$7)-ROW($A$3)+1),ROWS($1:1))),"")}
B10	{=IFERROR(INDEX(E$3:E$7,SMALL(IF($A$3:$A$7="Twitter",ROW($A$3:$A$7)-ROW($A$3)+1),ROWS($1:1))),"")}
C10	{=IFERROR(INDEX(F$3:F$7,SMALL(IF($A$3:$A$7="Twitter",ROW($A$3:$A$7)-ROW($A$3)+1),ROWS($1:1))),"")}
Press CTRL+SHIFT+ENTER to enter array formulas.

 

[matthewbutterworth]

Thank you Momentman! Solved! So much appreciation for your time. Thank you, again.