How to get a range as a picture on a userform

[MHD]

Hi

I have a range that I need to show on a user form, but I DO NOT want to use a list box. I want the range on the user form to look exactly like the original range on the sheet.

Anyone know the VBA to do this?



The range: sheets ("Invoice_Labor").range("A1:F35")
user form name: UserForm1
Command Button name: CB_Apply

Thanks

 

[Fluff]

Have a look here How to get a range as a picture on a userform

 

[MHD]

I have seen the results of this issue, but I have not been able to come up with the final code

 

[Fluff]

Sorry but don't understand what you mean. The thread I linked to has all the code.

 

[MHD]

Please can you copy the final code here!

 

[Fluff]

The code is all in post#3 of the linked thread.

 

[rlv01]

Here is a simpler example.

Sub Example()
    Dim WS As Worksheet, R As Range, Ch As Chart, ChO As ChartObject
    
    Set WS = ActiveSheet
    Set R = WS.Range("A1:D10") 'sample range to display on form
    
    R.CopyPicture xlScreen, xlPicture 'copy the range as a picture
    
    With R 'make temporary chart
        Set ChO = WS.ChartObjects.Add(Left:=.Left, Top:=.Top, Width:=.Width, Height:=.Height)
        Set Ch = ChO.Chart
        ChO.Activate 'this is important
    End With
    
    'paste range pic to chart and save it to a file.
    Ch.Paste
    Ch.Export Filename:="C:\Temp\RangePicture.jpg", Filtername:="JPG"
    DoEvents
    
    Application.DisplayAlerts = False
    ChO.Delete 'delete temporary chart
    Application.DisplayAlerts = True
    DoEvents
    
    'load image to userform (you will need to create this userform containing an image control for this example to work)
    UserForm1.Image1.AutoSize = True
    UserForm1.Image1.Picture = LoadPicture("C:\Temp\RangePicture.jpg") 'load .jpg from file
    UserForm1.Show
End Sub

 

[MHD]

The code works great
Thank you very much for the interaction

But I am still having a problem
The size of the image that the code has inserted does not correspond to the size of the image area in the user form.
Can we make the code automatically resize the image entered into the user's form?

Is there a solution for that, please

 

[MHD]

The code works great
Thank you very much for the interaction

But I am still having a problem
The size of the image that the code has inserted does not correspond to the size of the image area in the user form.
Can we make the code automatically resize the image entered into the user's form?

Is there a solution for that, please

Update: can I make the code to pop-up images in the real size as in the sheet in a new window (like a preview)?

 

[MHD]

@rlv01 @Fluff