How to identify which IF condition has been satisfied

[abi_learn_vba]

Hi,

I have below If Statement with three condition used with help of OR, at any point of time only one of these condition will be satisfied. Is there a way to identify which of these three OR condition has satisfied?

If Range("O" & n) = "" Or Range("O" & n) < Tdy Or Range("O" & n) = Tdy Then
'My Code
End if

Appreciate your help and support.

Thanks
-Abi

 

[abi_learn_vba]

Any Help. Is this possible? I tried it out in internet not able to find this.

 

[Jonmo1]

Not the way you have it written...

You'd have to structure it with an IF ElseIf type of thing..

If Range("O" & n) = "" Then
    Msgbox "It was blank"
ElseIf Range("O" & n) < Tdy Then
    Msgbox "It was less than " & Tdy
ElseIf Range("O" & n) = Tdy Then
    Msgbox "It was equal to " & Tdy
End If

 

[abi_learn_vba]

Thanks for your reply.

My requirement was not that.

My requirement is if any of these condition is true then i am going to perform same action, which may be for 10 to 15 lines of code. And based on which ever condition among it is satisfied i am going to perform single line code. My question is without using another if condition to check the value in Range("O" & n) will i be able to perform that single line of code.

If Range("O" & n) = "" Or Range("O" & n) < Tdy Or Range("O" & n) = Tdy Then

'My Code
'
'
'Need to check which of this condition is True.
'
Elseif 'Some other Condition'

'My codes

End if

Please let me know if you did not understand this.

Thanks
-Abi

 

[Jonmo1]

Try this

Dim OrTrue As Boolean
OrTrue = False
If Range("O" & n) = "" Then
    Msgbox "It was blank"
    OrTrue = True
ElseIf Range("O" & n) < Tdy Then
    Msgbox "It was less than " & Tdy
    OrTrue = True
ElseIf Range("O" & n) = Tdy Then
    Msgbox "It was equal to " & Tdy
    OrTrue = True
End If
 
If OrTrue = True Then
    'My Codes here
End If

 

[mikerickson]

Another approach

Dim Cond as Long

With Range("O" & n)
    Cond = (.Value = vbNullString) + 2 * (.Value < Tdy) + 3 * (.Value = Tdy)
End With

If Cond < 0 Then
    Rem do stuff
    Select Case Cond
        Case -1
            MsgBox "empty"
        Case -2
            MsgBox "LT Tdy"
        Case -3
            MsgBox "EQ Tdy"
    End Select
Else
    MsgBox "no condition met"
End If

 

[abi_learn_vba]

Thanks a lot for your responses.

Cheers
-Abi

 

[Jonmo1]

Glad to help.