If Cell range is nothing then

[fari1]

Dim dcell As Range, cellbelowd As Range
Set dcell = Worksheets("info").Cells.Find("Description", , xlValues, xlWhole, , , False)
Set cellbelowd = Worksheets("info").Cells.Find("*", dcell, xlValues, xlWhole, xlByColumns, xlNext)
                If cellbelowd Is Nothing Then
exit sub

in my above code, i want to do is to check if the next cell under the cell description is blank, if it is blank then exit sub.

but this code is not working somehow, any help

 

[AlphaFrog]

Dim dcell As Range
Set dcell = Worksheets("info").Cells.Find("Description", , xlValues, xlWhole, , , False)
If Not dcell Is Nothing Then
    If dcell.Offset(1).Value = "" Then Exit Sub
End If

 

[fari1]

it worked like a charm, thank u sooooooooooo much

 

[GTO]

'SlowHand' here... I see that you already rec'd a good answer - just as already typed and in case you want to verify that the sheet exists...

Option Explicit
    
Sub exa()
Dim wksInfo     As Worksheet
Dim dcell       As Range
    
    On Error Resume Next
    Set wksInfo = ThisWorkbook.Worksheets("info")
    
    If Err.Number = 9 Then
        MsgBox "Sheet ""info"" does not exist", vbOKOnly + vbInformation, "Error"
        On Error GoTo 0
        Exit Sub
    End If
    On Error GoTo 0
    
    Set dcell = wksInfo.Cells.Find("Description", , xlValues, xlWhole, , , False)
    
    If dcell Is Nothing Then
        MsgBox "Didn't find ""Description""", vbOKOnly + vbInformation, "Error"
        Exit Sub
    ElseIf dcell.Offset(1).Value = vbNullString Then
        Exit Sub
    Else
        MsgBox "'some more code"
    End If
End Sub

 

[fari1]

hi, its not about the sheet, i just wanted to see if a cell is b blank or not, the sheet is always there. thanks anyways for your help, greatly appreciated, will use this somewhere else, a i'm working on too much extensive project, thanks again