If Formula With Multiple Conditions

[Treesh1994]

I have this formula that is currently working, but I need to add one more section to it.

The Formula is

=IF(H26="","",IF(OR(H26={"99B","Deduct Front Cage","Deduct Rear Cage","Deduct Gun Mount","Deduct Seat","Deduct Window Guards","Deduct Console","Deduct Cupholder","Deduct Armrest","Deduct Swing Arm","Deduct Side Pole","Deduct Grille Lights"}),-AT$1,AT$1*(1+OR(H26={"ELUC3H010D","EMPS1STS4RBW","EMPS2QMS5RBW","EMPS2STS5RBW","ELUC3H010W","PLUCTCL1","EMPS1STS1W","EMPS1QMS4RBW","VTX609C","VTXADAPT","I3JC"}))))

I need to add an additional statement which is if the text contains "PMP2BKDGAJ" it needs to be multiplied by 4.

Any help would be greatly appreciated!

 

[SanjayGMusafir]

I need to add an additional statement which is if the text contains "PMP2BKDGAJ" it needs to be multiplied by 4.

Try this and revert -

=IFS(H26="","",
Iferror(Search("PMP2BKDGAJ",H26),0)>=1,AT$1*4,
OR(H26={"99B","Deduct Front Cage","Deduct Rear Cage","Deduct Gun Mount","Deduct Seat","Deduct Window Guards","Deduct Console","Deduct Cupholder","Deduct Armrest","Deduct Swing Arm","Deduct Side Pole","Deduct Grille Lights"}),-AT$1,
True,
AT$1*(1+OR(H26={"ELUC3H010D","EMPS1STS4RBW","EMPS2QMS5RBW","EMPS2STS5RBW","ELUC3H010W","PLUCTCL1","EMPS1STS1W","EMPS1QMS4RBW","VTX609C","VTXADAPT","I3JC"})))

 

[Treesh1994]

Try this and revert -

=IFS(H26="","",
Iferror(Search("PMP2BKDGAJ",H26),0)>=1,AT$1*4,
OR(H26={"99B","Deduct Front Cage","Deduct Rear Cage","Deduct Gun Mount","Deduct Seat","Deduct Window Guards","Deduct Console","Deduct Cupholder","Deduct Armrest","Deduct Swing Arm","Deduct Side Pole","Deduct Grille Lights"}),-AT$1,
True,
AT$1*(1+OR(H26={"ELUC3H010D","EMPS1STS4RBW","EMPS2QMS5RBW","EMPS2STS5RBW","ELUC3H010W","PLUCTCL1","EMPS1STS1W","EMPS1QMS4RBW","VTX609C","VTXADAPT","I3JC"})))

Yes,

That did work!

Thank you so much for your help on this!

 

[SanjayGMusafir]

Glad to help you. Thanks for your feedback.