IF Function - more advanced

[jma2fish]

I have read the other threads...I can get 75% of the "IF Function" below to work but when I add the 2nd portion of:IF(AND((B13)>250,(B13)<=350,2,2.5))), statement I then get an error.

=IF((B13)<=150,1,IF(AND((B13)>150,(B13)<=250),1.5,IF(AND((B13)>250,(B13)<=350,2,2.5)))


Cell B13 can be any number between 0-500 and is an AutoSUM cell from 2 other cells.

GOAL:
IF B13 <=150, return 1
IF B13 >150 but <=250, return 1.5
IF B13 >250 but <=350, return 2
IF B13 >351, return 2.5

 

[Yahya]

try if this will help
=LOOKUP(B13,{0;150;250;350},{1;1.5;2;2.5})

 

[martindwilson]

if you want 0=0
=LOOKUP(B13,{0,1,151,251,351},{0,1,1.5,2,5})
if 0=1

=LOOKUP(B13,{0,151,251,351},{1,1.5,2,5})

 

[water1355]

The OP's is missing a closing parenthesis in the second AND statement. Try:

=IF((B13)<=150,1,IF(AND((B13)>150,(B13)<=250),1.5,IF(AND((B13)>250,(B13)<=350),2,2.5)))

 

[jma2fish]

Wow, this feedback was fantastic. I really appreciate everyone's response. I did in fact try all 3 recommendations and all worked as planned.

I appreciate all the expertise. Thank you.

Regards from Asheville, North Carolina!

 

[Seti]

Actually, you don't need the AND conditions. Since the formula will execute left to right, if B13 is not less than 150, it must be greater than 150, so you don't need to check that condition. Here is a shorter version of your formula, corrected for the missing paren.

=IF(B13<=150,1,IF(B13<=250,1.5,IF(B13<=350,2,2.5)))