Insertion of picture by xls formula/ naming the picture

[luckiest man of the world]

Can anybody give me the idea that how to put the picture with a formula in xls sheet,
or if i click on one cell than respective picture should display in another cell

How it is possible

Thanks to you in advance.

 

[GlennUK]

How about putting the picture as the background for a cell comment?

... right-click comment border, Format Comment, Colors and Lines, Fill Color drop-down, Fill Effects, Picture, Select Picture.

 

[Misca]

Try something like:

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
Dim Pic As Object
Dim Rng As Range
Dim MyImageFolderPath As String
If Selection.Cells.Count > 1 Then Exit Sub
 
For Each Pic In ActiveSheet.Pictures
'Deletes the old images:
    Pic.Delete
Next Pic
Set Rng = Range("A1:D5")
MyImageFolderPath = "C:\My Images\"   'Change to match your folder
'Inserts the desired image:
Set Pic = ActiveSheet.Pictures.Insert(MyImageFolderPath & Target.Value)
'Adjusts the image to match the range:
With Pic
    .Top = Rng.Top
    .Left = Rng.Left
    .Height = Rng.Height
    .Width = Rng.Width  'Comment if you  want the height to set the size
End With
End Sub

The code deletes all the old images from the sheet and adds the new image from the set image folder.

If you already have all your images in your workbook use the following code instead:

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
Dim Pic As Object
Dim Rng As Range
On Error Resume Next
If Selection.Cells.Count > 1 Then Exit Sub
 
For Each Pic In ActiveSheet.Pictures
'Hides all the images:
    Pic.Visible = False
Next Pic
Set Rng = Range("A1:D5")    'Comment if you want to show the images where they are
MyImageFolderPath = "C:\Documents and Settings\All Users\Tiedostot\Omat kuvatiedostot\Kuvanäytteet\"
'Inserts the desired image:
Set Pic = ActiveSheet.Shapes(Target.Value)
'Adjusts the image to match the range:
With Pic
    .Visible = True
    .Top = Rng.Top
    .Left = Rng.Left
    .Height = Rng.Height
 '   .Width = Rng.Width  'Comment if you  want the height to set the size
End With
End Sub

Paste the code into the worksheet module of your workbook.