ISERROR within an OR statement with an IF statement

[BulletOLB]

Hello and thank you for any help. I am trying to perform a vlookup, nested with an if statement. I am very familiar with this basic process. My problem however arrises when I try to use an OR statement as the first condition within the IF statement. Essentially what I am trying to ask excel to do is..."If you find an error OR a 0 in cell Y35, perform this vlookup statement, else return the value in cell Y35" I have had success performing this process when just using the ISERROR statement as the first condition in the IF statement and when using just the =0 condition, but I have not been able to get both of them to work at the same time. Here is what my formula looks like currently but it does not work.

=IF(OR(ISERROR(Y35),Y35=0),VLOOKUP(R35,'Volume Table'!$A$1:$B$60,2,FALSE)/S35,Y35)

I have done my best to describe this so if you need further details let me know. Thanks

 

[rafaelspeixoto]

This happens because excel calculates everything inside the OR before giving it`s results. So, if Y35 is an error, the "Y35=0" comparison will end up in an error, messing with the whole formula. Try this longer version:
=IF(ISERROR(Y35),VLOOKUP(R35,'Volume Table'!$A$1:$B$60,2,FALSE)/S35,if(Y35=0,VLOOKUP(R35,'Volume Table'!$A$1:$B$60,2,FALSE)/S35,Y35))

 

[Aladin Akyurek]

Hello and thank you for any help. I am trying to perform a vlookup, nested with an if statement. I am very familiar with this basic process. My problem however arrises when I try to use an OR statement as the first condition within the IF statement. Essentially what I am trying to ask excel to do is..."If you find an error OR a 0 in cell Y35, perform this vlookup statement, else return the value in cell Y35" I have had success performing this process when just using the ISERROR statement as the first condition in the IF statement and when using just the =0 condition, but I have not been able to get both of them to work at the same time. Here is what my formula looks like currently but it does not work.

=IF(OR(ISERROR(Y35),Y35=0),VLOOKUP(R35,'Volume Table'!$A$1:$B$60,2,FALSE)/S35,Y35)

I have done my best to describe this so if you need further details let me know. Thanks

Try rather..

=IF(ISERROR(1/Y35),VLOOKUP(R35,'Volume Table'!$A$1:$B$60,2,0)/S35,Y35)

for, when there is an error value in Y35, OR will end up in error because of the 2nd term, never in TRUE.

 

[Jonmo1]

Welcome to the board...

You have to isolate the error in it's own IF (not in an OR or other function)
Because If Y35 IS an error, the ISERROR part is true,
But the OR MUST still test if Y35=0, and that results in an error.

Try

=IF(LOOKUP(9.99999999999999E+307,CHOOSE({1,2},0,Y35))=0,VLOOKUP(R35,'Volume Table'!$A$1:$B$60,2,FALSE)/S35,Y35)

 

[BulletOLB]

Thank you for the prompt help, these posts cleared up my issue right away! Couldn't have done it without your help. Have a good one.