List of months between and including 2 dates

[cajunlaroux]

Need a formula for D3 that i can drag down that will list all the months, including the start and end month, from B3 and B4. Assume the only data you're given is B3 and B4. Once B3 and B4 are provided, D3 on down will either populate automatically OR you manually drag down D3 formula until the end date month is reached and everything else below is blank. Thank you kindly!

 

[awoohaw]

try:

In Cell D3.

=TEXT(
DATE(YEAR(B3),SEQUENCE(MONTH(B4)-MONTH(B3)+1,,MONTH(B3),1),1),
"mmmm")

If you want to retain the date values, just take out the TEXT function and format the cells as "mmmm".
(this won't work if you wrap around December, but you can update the formula to get that accomplished).

 

[cajunlaroux]

Thank you! This worked perfectly!

 

[Dave Patton]

Dates and Time 2024.xlsm
	A	B	C	D
1
2
3		01-04-24		April
4		15-10-24		May
5				June
6				July
7				August
8				September
9				October
10
2b

Cell Formulas
Range	Formula
D3:D9	D3	=EDATE(B3,SEQUENCE(DATEDIF(B3,B4,"m")+1,,0))
Dynamic array formulas.

 

[awoohaw]

Thank you! This worked perfectly!

You're welcome. The post by @Dave Patton is shorter, and more succinct and wraps around year end.
Here is a LET() statement version that also considers wrapping around year end.

Best Wishes.

=LET(
SD,B3,
Nyrs,YEAR(B4)-YEAR(B3),
SMn,MONTH(B3),
EMn,(Nyrs*12)+MONTH(B4),
NMns,EMn-SMn,
EDATE(SD,SEQUENCE(NMns+1,,0,1)))