Listbox with web links

[ecoplan]

Hello everyone,
I'm trying to figure out how to be able to list web pages name from a worksheet into a listbox and then when clicking on that link and click the "Consult" button, the selected web page should open. I already have that code:

Private Declare Function ShellExecute Lib "shell32.dll" _
Alias "ShellExecuteA" (ByVal hWnd As Long, _
ByVal lpOperation As String, ByVal lpFile As String, _
ByVal lpParameters As String, ByVal lpDirectory As String, _
ByVal nShowCmd As Long) As Long

Private Sub CommandButton5_Click()
Dim URL As String
    Dim Result As Long
    With Me.list_links
        If .ListIndex <> -1 Then
            URL = .Value
            Result = ShellExecute(0&, vbNullString, URL, _
            vbNullString, vbNullString, vbNormalFocus)
            If Result < 32 Then MsgBox "Error", vbCritical
        Else
            MsgBox "Please make a selection and try again!", vbExclamation
        End If
    End With
End Sub

Private Sub UserForm_Initialize()
Dim cLinks As Range
Set ws = Worksheets("Links")
For Each cLinks In ws.Range("Links_title")
  With Me.list_links
    .AddItem cLinks.Value
  End With
Next cLinks
End Sub

But I'm getting the " Error" msgBox every links I try EXCEPT for the http://www.microsoft.com that opens "C:\WINNT\system32\Microsoft"

Here's the link to my dummy worksheet: https://www.dropbox.com/s/yb12bjpdw8u8j0b/links_workbook.xls

Thanks!

 

[ecoplan]

Sorry, this is the good link for the Worksheet: http://dl.dropbox.com/u/75538305/links_workbook.xls

 

[Norie]

You aren't listing the links in the listbox, all you have are the Page Titles, which aren't valid URLS.

To get the URL that corresponds to the selected title you can use this.

           URL = Worksheets("Links").Range("Links_Title")(.ListIndex + 1).Offset(, 1)

 

[ecoplan]

Wow, as simple as that. Thank you for your fast answer and explanation!