Log into Facebook account and post

[jaryszek]

Hi Guys,

I was looking trough internet and forums but i have not found anything helpful so I am writing here.

I have code and this is working for me to log on Facebook:

Sub Login_facebook()     
    Dim ie As Object
     
     Dim aelement
     Dim btnInput
     Dim btnInputer
     
    Set ie = CreateObject("InternetExplorer.Application")
     
    ie.navigate "http://www.facebook.com/login.php"
     
    ie.Visible = True
     
    Do While ie.Busy And Not ie.readyState = 4
        DoEvents
    Loop
     
    DoEvents
     
    ie.document.All.Item("email").Value = "xxx@com.pl"
    ie.document.All.Item("pass").Value = "yyyyy"
    ie.document.All.Item("login").Click
     Application.Wait (Now + TimeValue("00:00:02"))
    ie.navigate "https://www.facebook.com/groups/496722467127307/"
    Do While ie.Busy And Not ie.readyState = 4
        DoEvents
    Loop

I would like to additionally post.
But i don't know how to find a specific class and find a button "send".

The class for writing text in posting windows is "_1mf _1mj" but
ie.document.all.getbyclassname("_1mf _1mj") doesn't work for me.

Please help
Jacek Antek

 

[BarryL]

should it not be:

IE.document.getElementsByClassName("_1mf _1mj")

 

[jaryszek]

should it not be:

IE.document.getElementsByClassName("_1mf _1mj")

Yes,

but this is not working also.

Jacek

 

[jaryszek]

Hi Guys,

Happy New YEar!

Anyone who can help me with this ?

Jacek

 

[jaryszek]

Hi People,

anyone?

Jacek

 

[Ombir]

Can you create a dummy login account and share the login details so that I can help with you something.

 

[jaryszek]

Thanks Ombir!

Login-email: jaryszek@o2.pl
password: Testtest1234

Jacek Antek

 

[Ombir]

Try this:

Set reference to Microsoft Internet Controls and Microsoft HTML object library before executing this code.

Dim ie As InternetExplorer
Sub Ombir_03Dec2016()
Dim doc As HTMLDocument
Dim msg As String

Set ie = New InternetExplorer
msg = "Testing Finished"

With ie
    .Visible = True
    .Navigate "m.facebook.com"
    Call IEReady
End With

Set doc = ie.Document

doc.getElementById("email").Value = "jaryszek@o2.pl"
doc.getElementById("pass").Value = "Testtest1234"
doc.getElementById("login").Click
    Call IEReady
doc.getElementsByName("xc_message")(0).Value = msg
doc.getElementsByName("view_post")(0).Click
    Call IEReady
    ie.Quit
End Sub
Sub IEReady()
Do While ie.Busy: DoEvents: Loop
waitfor 1
    Do While ie.ReadyState <> 4
        waitfor 3
    Loop
End Sub
Sub waitfor(ByVal nSec As Long)
nSec = nSec + Timer
    Do While Timer < nSec
       DoEvents
    Loop
End Sub

 

[jaryszek]

Hi Ombir,

it is very clever way of doing this. Thank You very much for your help, this is working.

Could you please explain why did you do this via facebook mobile page?
It is simpler to get to specific class?

and what means "(0)" in this code? :

doc.getElementsByName("xc_message")(0).Value = msg

Please explain this I am very curious!

Jacek

 

[Ombir]

Mobile version is less complicated as compare to web version. That's why I choose it.

doc.getElementsByName("xc_message") always returns collection of items. 0 means first item in that collection, 1 means second and so on.

You can also try this web version:

Dim ie          As InternetExplorer
Sub Ombir_03Dec2016()
Dim doc         As HTMLDocument
Dim msg         As String
Dim Statusbox   As Object

Set ie = New InternetExplorer
msg = "Web Testing"

With ie
    .Visible = True
    .Navigate "www.facebook.com"
    Call IEReady
End With

Set doc = ie.Document

doc.getElementById("email").Value = "jaryszek@o2.pl"
doc.getElementById("pass").Value = "Testtest1234"
doc.getElementById("u_0_n").Click
    Call IEReady
Do While Statusbox Is Nothing
    On Error Resume Next
    Set Statusbox = doc.getElementsByName("xhpc_message")(0)
Loop
On Error GoTo 0
Statusbox.Value = msg
doc.getElementsByClassName("_42ft _4jy0 _ej1 _4jy3 _4jy1 selected _51sy")(0).Click
    Call IEReady
    ie.Quit
End Sub
Sub IEReady()
Do While ie.Busy: DoEvents: Loop
waitfor 1
    Do While ie.ReadyState <> 4
        waitfor 3
    Loop
End Sub
Sub waitfor(ByVal nSec As Long)
nSec = nSec + Timer
    Do While Timer < nSec
       DoEvents
    Loop
End Sub