Macro Issue

[awappel]

I have a macro that I am using that is supposed to copy a formula down an entire column. When I wrote the macro I did a scrolling copy downt he column to get the formula in each cell. I am getting an error that says "Run-time error '1004': Unable to se the ScrollRow property of the Window class" when I run the macro. Is there another way to copy down a formula that would work better in the Macro?

 

[VoG]

You can add a formula to a column all in one go like this:

Range("C1:C100").Formula="=A1+B1"

 

[lenze]

Hi and welcome to the board!!!

What Column are you is the formula in and how do you determine how far down??

lenze

 

[awappel]

I am using Column E, and I just had scrolled down to about 20 rows lower than my last data. So no really good process of determiing how far down I need to go.

 

[VoG]

Try like this - change the formula to suit

Sub Test2()
Dim LR As Long
LR = Cells.Find(What:="*", SearchDirection:=xlPrevious, SearchOrder:=xlByRows).Row
Range("E1:E" & LR).Formula = "=A1+B1"
End Sub

 

[lenze]

Assumming you have data in Column "A" and you want to copy down to the last row occupied, you can use something like this

Sub AddFormula()
Dim LR As Long
LR = Cells(Rows.Count, "A").End(xlUp).Row
Range("$E$2:E" & LR).Formula = "=C2+D2"
End Sub

lenze

 

[awappel]

Sub Test2()
Dim LR As Long
LR = Cells.Find(What:="*", SearchDirection:=xlPrevious, SearchOrder:=xlByRows).Row
Range("E1:E" & LR).Formula = "=CONCATENATE(B2," ",D2," ",C2)"
End Sub

Above is what I used, but it is telling me that the " " are causing expected end to the function or syntax error. I am just out of lunch because the Concantenate uses " "?

 

[VoG]

Try

Sub Test2()
Dim LR As Long
LR = Cells.Find(What:="*", SearchDirection:=xlPrevious, SearchOrder:=xlByRows).Row
Range("E1:E" & LR).Formula = "=CONCATENATE(B2,"" "",D2,"" "",C2)"
End Sub

 

[awappel]

wow~ thank you so much!