Macro that duplicates spread sheet and renames it

[Legacy 185660]

Hey again!
I need help with a simple macro, this is kind of 2 questions
I need a macro that will duplicate a sheet called "Template" and rename it as (Not sure how strings/macros work on excel so here is a rough interpretation based on my limited excel knowledge) Today() & " - " & Today + 4

So if i ran that script today it would duplicate the template and name it July 7 - July 11


Also, if anyone has any links to tutorials on macros, I would really like to learn

 

[VoG]

Try this

Sub test()
Sheets("Template").Copy after:=Sheets(Sheets.Count)
ActiveSheet.Name = Format(Date, "mmmm dd") & " - " & Format(Date + 4, "mmmm dd")
End Sub

 

[VoG]

For tutorials see Hiker's List http://www.mrexcel.com/forum/showpost.php?p=2676997&postcount=5

 

[Legacy 185660]

This is again, on google docs and is a tiny bit different

So do I just paste the code between

function myFunction() {

}

 

[VoG]

Sorry, I don't know anything about Google docs.

 

[Legacy 185660]

Actually I don't think google docs has any of the functionality.
Thanks anyways!

 

[Legacy 185660]

Ill be doing this in regular excel now, is there also an option that will automatically fill in the cell B2 with todays date?

 

[VoG]

Try

Sub test()
Sheets("Template").Copy after:=Sheets(Sheets.Count)
With ActiveSheet
    .Name = Format(Date, "mmmm dd") & " - " & Format(Date + 4, "mmmm dd")
    .Range("B2").Value = Date
End With
End Sub

 

[Legacy 185660]

Thanks! I mucked around with it a bit after that and made it so that it would auto update every monday on start up

[INDENT]Private Sub Workbook_Open()

'Checks if todays date is Monday, and will create a new sheet based on template
If Format(Date, "dddd") = "Monday" Then
    Call Duplicate_Template
End If

End Sub

[/INDENT] 
 Public Sub Duplicate_Template()

    Dim sh As Worksheet
    Dim name As String
    Dim nameTaken As Boolean
    
    'Will format date to "Dec 27 - 31" if it falls within same month, or "Dec 31 - Jan 4" if it does not
    If Format(Date, "mmm") = Format(Date + 4, "mmm") Then
        name = Format(Date, "mmm dd") & " - " & Format(Date + 4, "dd")
    Else
        name = Format(Date, "mmm dd") & " - " & Format(Date + 4, "mmm dd")
    End If
    
    For Each sh In Worksheets
        If [URL="http://sh.name/"]sh.name[/URL] Like name Then
            'Checks each sheet to make sure that the new sheet has not already been created
            nameTaken = True
            Exit For
        End If
    Next
    
    If nameTaken = False Then
            'If name is not taken, then it will create a duplicate of the template
            Sheets("Template").Copy after:=Sheets("Template")
            With ActiveSheet
                'Creates name of spreadsheet according to date
                .name = name
                'Inputs current date into cell "C1" to help populate graphs
                .Range("C1").Value = Date
            End With
    End If
    
End Sub