Macro to loop through sheets with a start point

[samokell]

Hi, I have the following macro, that just publishes every sheet in PDF:

Sub ExportToPDFs()
Dim ws As Worksheet

For Each ws In Worksheets
ws.Select
nm = ws.Name

ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, _
Filename:="C:\Exports\" & nm & ".pdf", _
Quality:=xlQualityStandard, IncludeDocProperties:=True, _
IgnorePrintAreas:=False, OpenAfterPublish:=False

Next ws

End Sub


However, I have about 20 sheets before the point I'd like to start publishing from:

So, I'd like this to loop through every sheet, but only AFTER the sheet called "Template - FX Only"

Any ideas?

 

[dmt32]

Hi,
welcome to forum

Untested but see if update to your code does what you want

Sub ExportToPDFs()
    Dim i As Integer
    Dim nm As String
    
    
    For i = Worksheets("Template - FX Only").Index + 1 To Worksheets.Count
        nm = Worksheets(i).Name
        Worksheets(i).ExportAsFixedFormat Type:=xlTypePDF, _
        Filename:="C:\Exports\" & nm & ".pdf", _
        Quality:=xlQualityStandard, IncludeDocProperties:=True, _
        IgnorePrintAreas:=False, OpenAfterPublish:=False
    
    Next i

End Sub

Dave

 

[samokell]

Works like a dream! Thanks very much