macro to split word

[AC]

I need a macro to split a word out of a cell and put each letter in a different cell, regardless of how long the word is, the trick is I need it to keep the first letter where it is and put the other letters up 2 rows and over 1 column, so if I put test in cell A50 the macro would leave t in A50 and put e in B48 s in C46 and t in D44. can this be done using excel 2003? Thanks

 

[mikerickson]

Something like this should work, but with decreasing row location (or column) there will be problems with words of more than 25 characters.

Sub test()
    Dim startCell As Range
    Dim rIncriment As Long, cIncriment As Long
    Dim wordToSplit As String
    Dim i As Long
    Set startCell = Range("A50")
    rIncriment = -2: cIncriment = 1
    
    wordToSplit = CStr(startCell.Value)
    For i = 0 To Len(wordToSplit) - 1
        startCell.Offset(i * rIncriment, i * cIncriment).Value = Mid(wordToSplit, i + 1, 1)
    Next i
End Sub

 

[CWatts]

Deleted my post. I misread and didn't offset the columns in my code.

 

[hiker95]

AC,

The macro will split a word in the ActiveCell (A50), per you request.

Enter the word test in cell A50. Then run the macro.



Sample data before the macro:

Excel Workbook
	A	B	C	D
43
44
45
46
47
48
49
50	test
Sheet1

After the macro:

Excel Workbook
	A	B	C	D
43
44				t
45
46			s
47
48		e
49
50	t
Sheet1

Please TEST this FIRST in a COPY of your workbook (always make a backup copy before trying new code, you never know what you might lose).


1. Copy the below code, by highlighting the code and pressing the keys CTRL + C
2. Open your workbook
3. Press the keys ALT + F11 to open the Visual Basic Editor
4. Press the keys ALT + I to activate the Insert menu
5. Press M to insert a Standard Module
6. Where the cursor is flashing, paste the code by pressing the keys CTRL + V
7. Press the keys ALT + Q to exit the Editor, and return to Excel
8. To run the macro from Excel, open the workbook, and press ALT + F8 to display the Run Macro Dialog. Double Click the macro's name to Run it.

Option Explicit
Sub SplitWord()
' hiker95, 04/13/2011
' http://www.mrexcel.com/forum/showthread.php?t=543443
Dim H As String, a As Long
Dim r As Long, c As Long
H = ActiveCell.Value
r = ActiveCell.Row
c = ActiveCell.Column
ActiveCell.Value = Left(H, 1)
For a = 2 To Len(H) Step 1
  r = r - 2
  c = c + 1
  Cells(r, c) = Mid(H, a, 1)
Next a
End Sub

Then run the SplitWord macro.

 

[CWatts]

I was robbed!

Edit, so was hiker!

 

[AC]

Thanks, both of them worked !