Macro, Unexpected Results

[Desu Nota from Columbus]

I wrote this macro:

Sub FAKE()
Dim i As Integer

Application.ScreenUpdating = False
With Sheets("SDIC")
    For i = 16 To 350
        If Range("L" & i).Value = False Then
            Range("A" & i & ":" & "L" & i).Delete (xlUp)
        End If
    Next i
    
 End With
 Application.ScreenUpdating = True
 
End Sub

In column L, starting at row 16 I have this formula

=SUMPRODUCT(--($S$16:$S$253=C16),--($T$16:$T$253=D16))>0

Which returns a true or false.

I would like the macro to delete range(A-L) for any row that this above formula returns false.

For some reason this did not happen with the above macro and I am not sure why.

I expect that once the macro is run, all the results will have a True in column L (which did not happen)

 

[JackDanIce]

I think your code is not deleting the rows you want because you're using With Sheets("SDIC") and then evaluating Range("L" & i), it should be .Range("L" & i) it's how WITH works..

A simple solution is to change your code to:

Sub FAKE()
Dim i As Integer

Application.ScreenUpdating = False
With Sheets("SDIC")
    For i = 350 to 16 Step -1
        If .Range("L" & i) = False Then .Range("A" & i & ":" & "L" & i).Delete 
    Next i
    
 End With
 Application.ScreenUpdating = True
 
End Sub

Although if you have no data after column L, then may be easier to delete the entire row, i.e.

If .Range("L" & i) = False Then .Rows(i).EntireRow.Delete

 

[Desu Nota from Columbus]

I will try this solution when I can and let you know how it goes.

I agree that it is much easier to delete the entire row, but I have data that cannot be deleted in subsequent columns.

Thanks for the help.

 

[JackDanIce]

You're welcome, let me know how it goes

 

[Desu Nota from Columbus]

very delayed response but it worked. Thanks again!