Merging all Workbooks in a Folder - worksheets with varying numbers of rows

[bradyj7]

Hi All,

The following code creates a new workbook. The code then takes each Excel workbook in the folder C:\Data and copies information from cells B2 through Q2 into the new workbook. In addition, the code puts the workbook file name in row A.

At the moment the code only copies the data in a single row - row 2. My question is, how can you modify the code to copy all rows that contain data. Also important, the number of rows in each workbook is not constant and varies.

I know I have to specify the range at this line

Set SourceRange = WorkBk.Worksheets(1).Range("B2:Q2")

However, I don't know what to do if the number of rows is unknown. I suppose you would need to find the last row that contains data.

Here is the full code.

Any help greatly appreciated.

John

Sub MergeAllWorkbooks()
    Dim SummarySheet As Worksheet
    Dim FolderPath As String
    Dim NRow As Long
    Dim FileName As String
    Dim WorkBk As Workbook
    Dim SourceRange As Range
    Dim DestRange As Range
    
    ' Create a new workbook and set a variable to the first sheet.
    Set SummarySheet = Workbooks.Add(xlWBATWorksheet).Worksheets(1)
    
    ' Modify this folder path to point to the files you want to use.
    FolderPath = "C:\Data\"
    
    ' NRow keeps track of where to insert new rows in the destination workbook.
    NRow = 1
    
    ' Call Dir the first time, pointing it to all Excel files in the folder path.
    FileName = Dir(FolderPath & "*.xl*")
    
    ' Loop until Dir returns an empty string.
    Do While FileName <> ""
        ' Open a workbook in the folder
        Set WorkBk = Workbooks.Open(FolderPath & FileName)
        
        ' Set the cell in column A to be the file name.
        SummarySheet.Range("A" & NRow).Value = FileName
        
        ' Set the source range to be B2 through Q2.
        ' Modify this range for your workbooks.
        ' It can span multiple rows.
        Set SourceRange = WorkBk.Worksheets(1).Range("B2:Q2")
        
        ' Set the destination range to start at column B and
        ' be the same size as the source range.
        Set DestRange = SummarySheet.Range("B" & NRow)
        Set DestRange = DestRange.Resize(SourceRange.Rows.Count, _
           SourceRange.Columns.Count)
           
        ' Copy over the values from the source to the destination.
        DestRange.Value = SourceRange.Value
        
        ' Increase NRow so that we know where to copy data next.
        NRow = NRow + DestRange.Rows.Count
        
        ' Close the source workbook without saving changes.
        WorkBk.Close savechanges:=False
        
        ' Use Dir to get the next file name.
        FileName = Dir()
    Loop
    
    ' Call AutoFit on the destination sheet so that all
    ' data is readable.
    SummarySheet.Columns.AutoFit
End Sub

 

[Andrew Poulsom]

Try:

    Dim LastRow As Long
    With WorkBk.Worksheets(1)
        LastRow = .Range("B" & .Rows.Count).End(xlUp).Row
        Set SourceRange = .Range("B2:Q" & LastRow)
    End With

 

[bradyj7]

Hi Andrew,

That worked.

Thank you

John