Message Box to Prompt Input Based on Another Cell

[welshraz]

Afternoon,

I want to create a prompt to ensure column O is input with data if the corresponding cell in column F contains the work "Repair". Column F contans dropdown options, and once a user choses one of the three options that contain the work repair, I would like a pop up box to prompt them to input a reason fior the repair in column O.

Any help greaty appreciated!

 

[Joe4]

Right-click on the sheet tab name at the bottom of your screen, select "View Code" and paste this VBA code in the VB Editor box that pops up:

Private Sub Worksheet_Change(ByVal Target As Range)

    Dim reason As String

'   Exit if multiple cells updated at once
    If Target.CountLarge > 1 Then Exit Sub
    
'   Run if value updated in column F and is "Repair"
    If Target.Column = 6 And Target.Value = "Repair" Then
'       Prompt for entry into column O
        reason = InputBox("Please enter the reason for the repair")
'       Populate column O
        Target.Offset(0, 9) = reason
    End If
    
End Sub

This should automatically do what you want.

 

[dmt32]

Hi
takes me awhile to type code these days but solution similar to @Joe4

Place code in your worksheets code page

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim Response    As Variant
    If Target.CountLarge > 1 Then Exit Sub
    On Error GoTo exitsub
    If Target.Column = 6 Then
        If Target.Value = "Repair" Then
            Do
                Response = InputBox("Please Enter Reason For Repair", "Reason")
                'cancel pressed
                If StrPtr(Response) = 0 Then Err.Raise 18
            Loop Until Len(Response) > 0
            'post response to Column O
            Application.EnableEvents = False
            Target.Offset(, 9).Value = Response
        End If
    End If
exitsub:
Application.EnableEvents = True
End Sub

Dave

 

[welshraz]

@Joe4 and @dmt32 thank you both. This is just what I was after.

 

[Joe4]

You are welcome.
Glad we were able to help!