Modify formula so it doesn't return 0 if not true

[suprsnipes]

How do I modify the following formula so it doesn't return 0 when it's not true?

=INDEX(F10:F297,MATCH(1,IF(E10:E297="Yes",1)),0)

Regards,
suprsnipes

 

[Peter_SSs]

When what is not true?

 

[suprsnipes]

When the cell in column F is = blank

 

[Peter_SSs]

When the cell in column F is = blank

Then try this
{=IF(INDEX(F10:F13,MATCH(1,IF(E10:E13="Yes",1)),0)="","",INDEX(F10:F13,MATCH(1,IF(E10:E13="Yes",1)),0))}

Edit: Oops, I forgot to increase the ranges back to yours but hopefully you picked that up.

But couldn't you just usr a simple INDEX/MATCH or VLOOKUP (with adjusted ranges)?

=IF(INDEX(F10:F22,MATCH("Yes",E10:E22,0))="","",INDEX(F10:F22,MATCH("Yes",E10:E22,0)))

=IF(VLOOKUP("Yes",E10:F22,2,0)="","",VLOOKUP("Yes",E10:F222,2,0))

 

[Aladin Akyurek]

Is the formula is expected to return a text value? If so, do you want return blank if the F-value does not exist i.e., empty?

 

[suprsnipes]

Yes that's what I want to do

 

[Aladin Akyurek]

Yes that's what I want to do

Control+shift+enter, not just enter:

=T(INDEX(F10:F297,MATCH(1,IF(E10:E297="Yes",1),0)))

Or, no CSE, just:

=T(INDEX(F10:F297,MATCH("Yes",E10:E297,0)))

If you also want to avoid #N/A...

2007 and later...

=IFERROR(T(INDEX(F10:F297,MATCH("Yes",E10:E297,0))),"")

All versions...

=LOOKUP(REPT("z",255),CHOOSE({1,2},"",T(INDEX(F10:F297,MATCH("Yes",E10:E297,0)))))

 

[suprsnipes]

Thanks very much

 

[Aladin Akyurek]

Thanks very much

You are welcome. & Thanks for providing us feedback.

 

[suprsnipes]

I used the following formula which worked perfectly.

=T(INDEX(F10:F297,MATCH("Yes",E10:E297,0)))

Appreciate it the suggestions Peter & Aladin.