move files from 1 folder to another based on cell values

[aravindhan_31]

Hi,

I would appreciate your help for the below.

I have
The source folder path Colum A,
file names in Column B
Destination path in Column C

Each file which are there in Column B has to be moved to folders which are there in Column C entere for each of these files.


Cross post: http://www.excelforum.com/excel-pro...1-folder-to-another-based-on-cell-values.html

 

[Domenic]

The following procedure moves the specified files listed in Column B from the source folder listed in Column A to the destination folder listed in Column C. If the file is moved successfully, a note to that effect will be placed in Column D. If a file does not exist within the source folder or if a file by the same name already exists within the destination folder, a note will be placed in Column D, accordingly. It also checks to see whether a path separator is included at the end of the string for the specified source and destination paths. If the path does not include a separator, it adds one at the end of the string.

Option Explicit

Sub MoveFiles()

    Dim SourcePath As String
    Dim DestPath As String
    Dim FileName As String
    Dim LastRow As Long
    Dim i As Long
    
    LastRow = Cells(Rows.Count, "A").End(xlUp).Row
    
    For i = 1 To LastRow
    
        FileName = Cells(i, "B").Value
    
        If Right(Cells(i, "A").Value, 1) <> Application.PathSeparator Then
            SourcePath = Cells(i, "A").Value & Application.PathSeparator
        Else
            SourcePath = Cells(i, "A").Value
        End If
        
        If Right(Cells(i, "C").Value, 1) <> Application.PathSeparator Then
            DestPath = Cells(i, "C").Value & Application.PathSeparator
        Else
            DestPath = Cells(i, "C").Value
        End If
        
        If Dir(SourcePath & FileName) = "" Then
            Cells(i, "D").Value = "Source file does not exist."
        ElseIf Dir(DestPath & FileName) <> "" Then
            Cells(i, "D").Value = "File already exists."
        Else
            Name SourcePath & FileName As DestPath & FileName
            Cells(i, "D").Value = "File moved to new location"
        End If
        
    Next i
        
End Sub

 

[aravindhan_31]

Hi,

Thanks for your help it works fine

 

[lukhmanazeez94]

Need help create destination folders if they do not exist within this VBA code.

 

[lukhmanazeez94]

Sub MoveFiles()
'https://www.mrexcel.com/board/threads/move-files-from-1-folder-to-another-based-on-cell-values.490948/

Dim SourcePath As String
Dim DestPath As String
Dim FileName As String
Dim LastRow As Long
Dim i As Long
    
    LastRow = Cells(Rows.Count, "A").End(xlUp).Row
    For i = 1 To LastRow
        FileName = Cells(i, "B").Value
        If Right(Cells(i, "A").Value, 1) <> Application.PathSeparator Then
            SourcePath = Cells(i, "A").Value & Application.PathSeparator
        Else
            SourcePath = Cells(i, "A").Value
        End If
        If Right(Cells(i, "C").Value, 1) <> Application.PathSeparator Then
            DestPath = Cells(i, "C").Value & Application.PathSeparator
                [B]If Len(Dir(DestPath, vbDirectory)) = 0 Then MkDir DestPath
                End If[/B]
        Else
            DestPath = Cells(i, "C").Value
        End If
        If Dir(SourcePath & FileName) = "" Then
            Cells(i, "D").Value = "Source file does not exist."
        ElseIf Dir(DestPath & FileName) <> "" Then
            Cells(i, "D").Value = "File already exists."
        Else
            Name SourcePath & FileName As DestPath & FileName
            Cells(i, "D").Value = "File moved to new location"
        End If
    Next i
End Sub

I had added the
If Len(Dir(DestPath, vbDirectory)) = 0 Then MkDir DestPath
End If
in above code to create new folders based on column C.

Create folder path if does not exist (saving from VBA)

I have a list of items in a sheet like so: My code goes through each row and groups the supplier and copies some information into a work book for each supplier. In this scenario there are 2 unique

stackoverflow.com

I tried to implement suggestions from above link to the code.

Need Help.