Moving between other workbooks in VBA

[TheWennerWoman]

Hello,

The end user selects two files which populate two cells in my workbook, named ranges file_1 and file_2. These aren't just filenames, they also include the full filepath.

I want to start moving data between the two files but have come up with an "Object Required" error. This is my code, can anyone see what I'm doing wrong?

Sub open_files()

Application.ScreenUpdating = False

File_1 = Range("file_1").Value
File_2 = Range("file_2").Value
Workbooks.Open Filename:=File_1
Workbooks.Open Filename:=File_2
File_1.Activate '<----this line is the problem
Columns("A:A").Copy
End Sub

Thanks in advance!

 

[RoryA]

File_1 is just text, not a workbook object. You should store the workbooks in variables:

Sub open_files()

Application.ScreenUpdating = False

File_1 = Range("file_1").Value
File_2 = Range("file_2").Value
dim wb1 as workbook
set wb1 = Workbooks.Open(Filename:=File_1)
dim wb2 as workbook
set wb2 = Workbooks.Open(Filename:=File_2)
wb1.Activate 
Columns("A:A").Copy
End Sub

 

[Georgiboy]

For speed you should avoid activating the workbooks and just refer to their variable names:

Option Explicit
Sub open_files()
    Dim wb1 As Workbook, wb2 As Workbook
    Dim File_1 As String, File_2 As String
    
    File_1 = Range("file_1").Value
    File_2 = Range("file_2").Value
    
    Set wb1 = Workbooks.Open(File_1)
    Set wb2 = Workbooks.Open(File_2)

    wb1.Sheets("Sheet1").Columns("A:A").Copy
    wb2.Sheets("Sheet1").Columns("A:A").PasteSpecial (xlAll)
    Application.CutCopyMode = False
End Sub

 

[TheWennerWoman]

Thanks so much both, both answers work perfectly but I can only mark one as the solution