Multiple match in RE

[AlexanderBB]

I found an interesting routine to extract a bracketed part of a string with regular expression.

excel - Get the value between the brackets - Stack Overflow

One of things it says is multiple matches in one string if required

But I cannot figure out how it can return more than one match. Can anyone else?

 

[pgc01]

Hi

To get multiple matches you have to set the .Global property to True (the default is false).

This is an example.
I changed the pattern because I don't see why to use submatches on such a simple problem.

I added another parameter to the function that allows you to say which bracket pair you want.

Try:

Function MyGetParen(strIn As String, lInd As Long) As String
    Dim objRegex As Object
    Dim objRegMC As Object
    Set objRegex = CreateObject("vbscript.regexp")
    With objRegex
        .Pattern = "\([^)]+\)"
        .Global = True
        Set objRegMC = .Execute(strIn)
        If objRegMC.Count >= lInd Then
            MyGetParen = objRegMC(lInd - 1)
        Else
            MyGetParen = "No match"
        End If
    End With
    Set objRegex = Nothing
End Function

Sub Test()
MsgBox GetParen("Not me")
MsgBox MyGetParen("V2397(+60)(-50)(100)", 1)
MsgBox MyGetParen("V2397(+60)(-50)(100)", 2)
MsgBox MyGetParen("V2397(+60)(-50)(100)", 3)
MsgBox MyGetParen("V2397(+60)(-50)(100)", 4)
End Sub

 

[AlexanderBB]

Hi PGC.. that sorts that, he hadn't included it. In my case I don't know in advance which brackets, so want to know if there's more than one
and can see from your code that's objRegMC.Count.

Cool, thanks

 

[pgc01]

I'm glad it helped.

P. S. I assumed that this is to study regex syntax.
You could use a much simpler function for the same purpose, like:

Function MyGetParen(strIn As String, lInd As Long) As String
MyGetParen = "No match"
On Error Resume Next
MyGetParen = Split(Split(strIn, "(")(lInd), ")")(0)
End Function

I tested with:

Sub Test()
MsgBox MyGetParen("Not me", 1)
MsgBox MyGetParen("V2397(+60)(-50)(100)", 1)
MsgBox MyGetParen("V2397(+60)(-50)(100)", 2)
MsgBox MyGetParen("V2397(+60)(-50)(100)", 3)
MsgBox MyGetParen("V2397(+60)(-50)(100)", 4)
End Sub

 

[AlexanderBB]

Yes, quite neat ! Just wondering how to add a bracketed items count to it...

 

[pgc01]

The count would be

MsgBox UBound(Split(strIn, "("))

 

[AlexanderBB]

Ah, of course
Thanks..
.

 

[pgc01]

You're welcome.