Multiple OptionButton Groups on Same Userform

[sarasotavince]

Hello one and all:

I have multiple optionbutton groupings on the same userform. I am using the group name in the properties box (set1, set2, set3, etc) so that only one choice can be made from each group. I can write code to get the first group to operate but I cannot figure out how to use the group name to control the code for each additional grouping (set1, set2, set2, etc). Can someone help me modify this code to reflect only a specific group (say, set1) and I can repeat the process with each group. Much thanks.

For i = 1 To 12 'THIS IS THE FIRST SET OF OPTIONBUTTONS
If Me.Controls("OptionButton" & i).Value = True Then<?xml:namespace prefix = o ns = "urn:schemas-microsoft-comfficeffice" /><o></o>
MsgBox "Found it" 'OR WRITE THE CAPTION VALUE TO SOME SHEET
Exit For<o></o>
End If<o></o>
Next i

I figure there has to be a way to use the group name to control the code. I will end up having 6 or 7 groups and each selection from within each group upon exit will do something different. (I can handle this part).

One last thing. I do not want to use frames. And wouldn't the code be basically the same using a frame name instead of a group name? The reason I ask is because I might want to use a frame for this very same problem on another project.

Thanks so much.

 

[mikerickson]

You could use something like this. If you use this, note that OptButtonChosenFromGroup will return Nothing if no button from the group is selected.

Function OptButtonChosenFromGroup(groupName As String) As msforms.OptionButton
    Dim oneControl As Object
    For Each oneControl In Me.Controls
        If TypeName(oneControl) = "OptionButton" Then
            If oneControl.Value And oneControl.groupName = groupName Then
                Set OptButtonChosenFromGroup = oneControl
                Exit Function
            End If
        End If
    Next oneControl
End Function

Private Sub UserForm_Click()
    MsgBox OptButtonChosenFromGroup("set1").Name & " chosen." _
        & vbCr & OptButtonChosenFromGroup("set2").Name & " chosen."
End Sub

 

[sarasotavince]

Thanks mikerickson !!


I studied your code and was able to adapt it to my situation. Since I need to write the caption from each set to a WORKSHEET, I was able to use:


Sheets("SHEETNAME").Cells(11, 10).Value = OptButtonChosenFromGroup("set1").Caption


You rock.