#N/A

[palley]

I use this line in my spreadsheet to pull in a formula. If it finds a formula it pulls it in. If not it puts #N/A. Is there anything I can add to the vlookup line that will keep it from putting #N/A on the other lines?

=VLOOKUP(A3906,DESC,2,FALSE)

 

[Brian Walters]

=If(Iserror(VLOOKUP(A3906,DESC,2,FALSE)),"",VLOOKUP(A3906,DESC,2,FALSE))

 

[palley]

=If(Iserror(VLOOKUP(A3906,DESC,2,FALSE)),"",VLOOKUP(A3906,DESC,2,FALSE))

does not appear to work

 

[Scott Huish]

Normally I would use ISNUMBER MATCH, but since you are using a named range. ISNA should suffice:

=IF(ISNA(VLOOKUP(A3906,DESC,2,FALSE)),"",VLOOKUP(A3906,DESC,2,FALSE))

 

[Haseeb Avarakkan]

Try;

If the output is number,

=LOOKUP(1E+307,CHOOSE({1,2},0,VLOOKUP(A3906,DESC,2,FALSE)))

Should return zero, if it is #N/A

If output is text,

=LOOKUP(REPT("Z",250),CHOOSE({1,2},"",VLOOKUP(A3906,DESC,2,FALSE)))

Should return blank, id it is #N/A

 

[Aladin Akyurek]

I use this line in my spreadsheet to pull in a formula. If it finds a formula it pulls it in. If not it puts #N/A. Is there anything I can add to the vlookup line that will keep it from putting #N/A on the other lines?

=VLOOKUP(A3906,DESC,2,FALSE)

What does mean "to pull in a formula"? Could you give an exemple?

 

[palley]

=VLOOKUP(A3906,DESC,2,FALSE)
on the table named desc I have a list of formulas and a number assigned to this formula. On the pivot table when it finds the number it looks at desc for that number and returns the formula assigned to it

 

[Aladin Akyurek]

=VLOOKUP(A3906,DESC,2,FALSE)
on the table named desc I have a list of formulas and a number assigned to this formula. On the pivot table when it finds the number it looks at desc for that number and returns the formula assigned to it

I'd like very much to see a formula that gets pulled by the above formula.
Is it a string what it returns or a number following a calculation?

 

[palley]

desc TAB
COLUMN A COLUMN B
TENN147 TEST1
TENN148 TEST2
TENN149 TEST3

ON PIVOT TABLE WHEN IT SEES TENN147 IT PUTS TEST1 IN THE 2ND COLUMN

 

[Aladin Akyurek]

desc TAB
COLUMN A COLUMN B
TENN147 TEST1
TENN148 TEST2
TENN149 TEST3

ON PIVOT TABLE WHEN IT SEES TENN147 IT PUTS TEST1 IN THE 2ND COLUMN

Ok. Thanks.

If you are on 2007 or later...

=IFERROR(VLOOKUP(A3906,DESC,2,0),"Not Found")

You can replace the last bit anything more appropriate, including "", a blank.
By the way, 0 as fourth argument stands for FALSE, 1 would stand for TRUE.

On a previous version, you have a few options like...

=LOOKUP(REPT("z",255),CHOOSE({1,2},"Not Found",VLOOKUP(A3906,DESC,2,0)))

=IF(ISNA(VLOOKUP(A3906,DESC,1,0),"Not Found",VLOOKUP(A3906,DESC,2,0))