Name a BuildFreeform shape Question

[julhs]

The code below constructs a Freeform shape, how can I give the shape a meaning full/given name so that it is not simply given “Freeform ??? what ever” when it gets converted to a shape.

Sub DrawFreeformME()
Dim ws As Worksheet, fb As FreeFormBuilder
Set ws = ActiveSheet
' Create freeform
Set fb = ws.Shapes.BuildFreeform(msoEditingAuto, 380, 230)
' Add segments.
fb.AddNodes msoSegmentCurve, msoEditingCorner, _
380, 230, 400, 250, 450, 300
fb.AddNodes msoSegmentCurve, msoEditingAuto, 480, 200
fb.AddNodes msoSegmentLine, msoEditingAuto, 480, 400
fb.AddNodes msoSegmentLine, msoEditingAuto, 380, 230
' Render drawing.
fb.ConvertToShape
End Sub

 

[Micron]

Perhaps

Sub DrawFreeformME()
Dim ws As Worksheet, fb As FreeformBuilder
Dim shp As Shape

Set ws = ActiveSheet
' Create freeform
Set fb = ws.Shapes.BuildFreeform(msoEditingAuto, 380, 230)
' Add segments.
fb.AddNodes msoSegmentCurve, msoEditingCorner, _
380, 230, 400, 250, 450, 300
fb.AddNodes msoSegmentCurve, msoEditingAuto, 480, 200
fb.AddNodes msoSegmentLine, msoEditingAuto, 480, 400
fb.AddNodes msoSegmentLine, msoEditingAuto, 380, 230
' Render drawing.
Set shp = fb.ConvertToShape
shp.Name = "Blue Shape3"

End Sub

 

[Marius44]

HI
After fb.ConvertToShape add this code

With ActiveSheet
  .Shapes(.Shapes.Count).Name = "YourName"
End With

Hi,
Mario

 

[julhs]

Thank you Micron, you’re a life saver!
I’d been struggling with this for ages and it was doing my nut in!!
I can now set about positioning the Freeform shape on the sheet in the same sort of way that you do when you use a predefined mso shape, ie

AddShape(msoShape?????, 250, 350, 100, 200)

‘250, 350 being its position & 100, 200 being its size

 

[Micron]

The other suggestion would likely work to address your posted concern, but the advantage of creating an object variable for this would be that you could do other things with or to it in that code without having to continually reference the Shapes collection.
Glad I could help. If you have a solution, perhaps mark this as solved so that others looking to help can bypass this one.

 

[julhs]

the advantage of creating an object variable for this would be that you could do other things with or to it in that code without having to continually reference the Shapes collection.

Did think using object variable was going to be easy to reference further down the line, but defining the Freeform shape as an object was what I was struggling with!!

 

[Marius44]

HI

@Micron
I have to agree that your suggestion is more streamlined than mine. Compliments.
I disagree, however, with the point of continually referring to the Shapes Collection; at that point you refer to the image created by its name, the one you gave it.
Do you agree?

HI,
Mario

 

[Micron]

If I understand your suggestion, then IMO this or anything similar is still a reference to the shapes collection
ActiveSheet.Shapes(Shapes.Count).somePropertyHere = somePropertyValueHere

AFAIK, (Shapes.Count) is the reference to the shape with the highest index number; index is a property of the Shapes collection. I say AFAIK because my knowledge of Access vba is far better than Excel vba but I do find that many of the basic principles apply to both. So if you have an example of how to refer to it by name only (not by index (which can be a number or its name) and not by using an object variable), can you share it?
Thanks.

 

[Marius44]

HI
As you can see from the last line of code, I select the created shape by its name.
Here's what I mean.

Sub Macro3()
Dim ws As Worksheet, fb As FreeformBuilder
Set ws = ActiveSheet
' Create freeform
Set fb = ws.Shapes.BuildFreeform(msoEditingAuto, 380, 230)
' Add segments.
fb.AddNodes msoSegmentCurve, msoEditingCorner, _
380, 230, 400, 250, 450, 300
fb.AddNodes msoSegmentCurve, msoEditingAuto, 480, 200
fb.AddNodes msoSegmentLine, msoEditingAuto, 480, 400
fb.AddNodes msoSegmentLine, msoEditingAuto, 380, 230
' Render drawing.
fb.ConvertToShape
'change name
With ActiveSheet
  .Shapes(.Shapes.Count).Name = "YourName"
End With

ActiveSheet.Shapes("YourName").Select   ' <---xxxxxxxxxxx '
End Sub

HI,
Mario

 

[Micron]

OK, Shapes("YourName") is still a reference to the shapes collection that belongs to the active sheet by using the shape name instead of a number for the index property value. Not that it's wrong, just that I consider creating an object variable and storing the shape in it is just marginally more efficient if repeated references to it will be used.

So shp.name, or shp.Select or whatever, eliminates referring to the active sheet and drilling down to the shapes collection because the actual shape is in the variable. Same as if you used a With block:

With shp
    .Select
    .etc
End With

vs

With ActiveSheet.Shapes("myShape")
    .Select
    .etc
End With

For subsequent references to a shape, I don't see how you can escape starting at the sheet level, referring to its shape collection, then to a shape via the index property (by name or number) without storing the shape in a variable. Granted, putting the shape in an object variable requires that chain of references, but it is only done once.