non responsive web site message/timer

[mummbles74]

I have this code in a piece of code that I use to copy information from a website into my work sheet.

Set IE = CreateObject("InternetExplorer.application")
IE.Visible = True
IE.Navigate2 "extranet.deritend.co.uk/portal/login.php"
Do
If IE.readyState = 4 Then
IE.Visible = False
Exit Do
Else
DoEvents
End If

The web site is sometime un able to load because it is being updated, what I would like to do is for a msgbox or similar to pop up after a certain amount of time if the webpage has not loaded and use this to end the sub.

Any help appreciated, thank you in anticipation

Mummbles74

 

[John_w]

Try something like this:

Sub IE1()

    Dim IE As InternetExplorer
    Dim URL As String
    Dim timeout As Date
    
    URL = "http://www.mrexcel.com/forum/forumdisplay.php?f=3"
    
    Set IE = New InternetExplorer
    
    timeout = Now + TimeValue("00:00:03")   '3 seconds
    
    With IE
        .Navigate URL
        While .ReadyState <> READYSTATE_COMPLETE And Now < timeout
            DoEvents
        Wend
        
        If .ReadyState <> READYSTATE_COMPLETE Then
            MsgBox "Timeout occurred waiting for " & URL
            .Quit
            Set IE = Nothing
            Exit Sub
        Else
            .Visible = True
        End If
        
    End With
    
End Sub