On Error Resume Next allowing error to occur

[reneuend]

I got this following function from http://www.cpearson.com/excel/vbaarrays.htm and would like to use it, but the "On Error Resume Next" code is not working where they are purposely allowing an error to occur at the line: N = UBound(Arr, 1).

What do I need to do to make this not display the error dialog?

Public Function IsArrayAllocated(Arr As Variant) As Boolean
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' IsArrayAllocated
' Returns TRUE if the array is allocated (either a static array or a dynamic array that has been
' sized with Redim) or FALSE if the array is not allocated (a dynamic that has not yet
' been sized with Redim, or a dynamic array that has been Erased). Static arrays are always
' allocated.
'
' The VBA IsArray function indicates whether a variable is an array, but it does not
' distinguish between allocated and unallocated arrays. It will return TRUE for both
' allocated and unallocated arrays. This function tests whether the array has actually
' been allocated.
'
' This function is just the reverse of IsArrayEmpty.
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Dim N As Long
On Error Resume Next
' if Arr is not an array, return FALSE and get out.
If IsArray(Arr) = False Then
    IsArrayAllocated = False
    Exit Function
End If
' Attempt to get the UBound of the array. If the array has not been allocated,
' an error will occur. Test Err.Number to see if an error occurred.
N = UBound(Arr, 1)
If (Err.Number = 0) Then
    ''''''''''''''''''''''''''''''''''''''
    ' Under some circumstances, if an array
    ' is not allocated, Err.Number will be
    ' 0. To acccomodate this case, we test
    ' whether LBound <= Ubound. If this
    ' is True, the array is allocated. Otherwise,
    ' the array is not allocated.
    '''''''''''''''''''''''''''''''''''''''
    If LBound(Arr) <= UBound(Arr) Then
        ' no error. array has been allocated.
        IsArrayAllocated = True
    Else
        IsArrayAllocated = False
    End If
Else
    ' error. unallocated array
    IsArrayAllocated = False
End If
End Function

Thanks for any suggestions!

 

[GTO]

Just to be sure, are you stepping through this?

 

[RoryA]

Do you have your VBEditor set to break on all errors?

 

[monirg]

reneuend;

As a footnote, you may want to look at the following Thread for the possible implications of using "On Error Resume Next":
VBA Help: "On Error Resume Next" ??
http://www.mrexcel.com/forum/showthread.php?t=497939

Regards.

 

[reneuend]

Thanks for all the replies!!!!

GTO: Yes, I'm stepping through the code.

rorya: Yes, I have it set to break on all errors...would that cause it to ignore the Resume Next statement?

monirg: I haven't read about the implications. I'll take a look. But, I really need to have a way to check if an array has been allocated.

 

[reneuend]

I changed it so it wouldn't break on all errors and it works. Now, to go read about the implications!

Thanks everyone!

 

[RoryA]

If you set it to break on all errors, then any error handler will simply be ignored.