Open multiple selected workbooks and copy the range from each sheet into destination then print, and repeat until last selected workbook.

[KyleJackMorrison]

Hello,

I would like some help with customising this bit of code below.

What I would like this to do is to prompt the user to select 1 or more .CSV files, and copy the selected range from each file into my main workbook, print that sheet then continue to the next document that was previously select.

The code below does this for only 1 selected document.

Any help would be appreciated.

Kyle

Sub GetFileCopyData()
    Application.ScreenUpdating = False
    Application.EnableEvents = False
        Dim Fname As String
        Dim SrcWbk As Workbook
        Dim DestWbk As Workbook
        
        Set DestWbk = ThisWorkbook
        
        Fname = Application.GetOpenFilename(FileFilter:="Excel Files (*.csv*), *.csv*", Title:="Select a File")
        If Fname = "False" Then
            MsgBox "No file was selected", vbInformation
            Exit Sub
        End If
        Set SrcWbk = Workbooks.Open(Fname)
        
        SrcWbk.Sheets(1).Range("B3").Copy DestWbk.Sheets("PASTE").Range("A1")
        DestWbk.Sheets("TEMPLATE").printout preview:= False

        SrcWbk.Close False
    Application.ScreenUpdating = True
    Application.EnableEvents = True
End Sub

 

[JLGWhiz]

There are two things a user will need to know to use this code. 1) How to use the FileName dialog box to locate the applicable directory and 2) how to hold down Ctrl while seleccting multiple files. If the user can master those two items, then the code should do what you want.

Sub GetFileCopyData()
    Application.ScreenUpdating = False
    Application.EnableEvents = False
        Dim Fname As Variant
        Dim SrcWbk As Workbook
        Dim DestWbk As Workbook
        Set DestWbk = ThisWorkbook
        Fname = Application.GetOpenFilename(FileFilter:="Excel Files (*.csv), *.csv", Title:="Select 1 Or More Files", MultiSelect:=True)
        If fName = False Then
            MsgBox "No file was selected", vbInformation
            Exit Sub
        End If
        For i = LBound(Fname) To UBound(Fname)
        Set SrcWbk = Workbooks.Open(Fname(i))
        SrcWbk.Sheets(1).Range("B3").Copy DestWbk.Sheets("PASTE").Range("A1")
        DestWbk.Sheets("TEMPLATE").PrintOut preview:=False
        SrcWbk.Close False
        Next
    Application.ScreenUpdating = True
    Application.EnableEvents = True
End Sub