Paste values number of times based off count in specific cell

[nidg]

I'm trying to paste a value from one cell into another column a number of times. The number of times the value will be copied is determined by a counter. I have thousands of these values that I want to do this for which is why i need a quick way to do it.

Would love some suggestions. Thanks

 

[kevin9999]

I'm sure there'll be a way of doing this with functions (I note you have 365) but here's a VBA method. Change the assumptions as marked in the code.

Option Explicit
Sub nidg()
    Dim ws As Worksheet, rng As Range
    Dim LCol As Long, TotRows As Long, TotCols As Long
    Set ws = Worksheets("Sheet1")                           '<-- *** Change to actual sheet name ***
    LCol = ws.Cells(1, Columns.Count).End(xlToLeft).Column
    Set rng = ws.Range(ws.Cells(1, 3), ws.Cells(2, LCol))   '<-- *** Assumes first cell is C1 ***
    TotRows = Application.Sum(rng.Rows(2))
    TotCols = rng.Columns.Count
    
    Dim a, b, i As Long, j As Long, k As Long
    ReDim a(1 To TotRows, 1 To 1)
    b = rng
    k = 1
    For i = 1 To TotCols
        For j = 1 To b(2, i)
            a(k, 1) = b(1, i)
            k = k + 1
        Next j
    Next i
    ws.Range("C5").Resize(UBound(a, 1), 1).Value = a        '<-- *** Assumes destination cell is C5 ***
End Sub

Before:

nidg.xlsm
	C	D	E	F
1	18/11/2023	20/11/2023	21/11/2023	22/11/2023
2	6	1	2	3
3
4
5
6
Sheet1

After:

nidg.xlsm
	C	D	E	F
1	18/11/2023	20/11/2023	21/11/2023	22/11/2023
2	6	1	2	3
3
4
5	18/11/2023
6	18/11/2023
7	18/11/2023
8	18/11/2023
9	18/11/2023
10	18/11/2023
11	20/11/2023
12	21/11/2023
13	21/11/2023
14	22/11/2023
15	22/11/2023
16	22/11/2023
17
Sheet1

 

[Fluff]

Hi & welcome to MrExcel.
A formula option

Fluff.xlsm
	A	B	C	D	E	F
1			18/11/2023	20/11/2023	21/11/2023	22/11/2023
2			6	1	2	3
3
4
5			18/11/2023
6			18/11/2023
7			18/11/2023
8			18/11/2023
9			18/11/2023
10			18/11/2023
11			20/11/2023
12			21/11/2023
13			21/11/2023
14			22/11/2023
15			22/11/2023
16			22/11/2023
17
Sheet7

Cell Formulas
Range	Formula
C5:C16	C5	=TOCOL(IF(SEQUENCE(MAX(C2:F2))<=C2:F2,C1:F1,1/0),2,1)
Dynamic array formulas.