Permutations with no Repetition and NO Duplicates

[excelNewbie22]

hi,
i need a way to generate Permutations with no repeats, and no duplicates
either with a formula or an udf,

so if i have the numbers: 1-2-3-4 i'll get:
[1,2,3,4],[1,2,4,3],[1,3,2,4],[1,3,4,2],[1,4,2,3],[1,4,3,2],[2,1,3,4],[2,1,4,3],[2,3,1,4],[2,3,4,1],[2,4,1,3],[2,4,3,1],[3,1,2,4],[3,1,4,2],[3,2,1,4],[3,2,4,1],[3,4,1,2],[3,4,2,1],[4,1,2,3],[4,1,3,2],[4,2,1,3],[4,2,3,1],[4,3,1,2],[4,3,2,1]
ignore the brackets
total of 24 permutations with no duplicates

and, this is the problematic part, if i have 1-2-3-3 i want to get:
[1,2,3,3],[1,3,2,3],[1,3,3,2],[2,1,3,3],[2,3,1,3],[2,3,3,1],[3,1,2,3],[3,1,3,2],[3,2,1,3],[3,2,3,1],[3,3,1,2],[3,3,2,1]
total of 12 only, with no duplicates

and if 1-2-2-2 i want to get: [1,2,2,2],[2,1,2,2],[2,2,1,2],[2,2,2,1] only 4 in total

found an udf in get-digital-help.com but it return duplicates,

also i have this:

=INDEX(A2:D2,MID(BASE(SEQUENCE(PERMUTATIONA(COUNTA(A2:D2),4))-1,COUNTA(A2:D2),4),SEQUENCE(,4),1)+1)

but it returned all premutations with duplicates and repetitions

can it be done?

 

[Fluff]

How about

Fluff.xlsm
	A	B	C	D
1
2	1	2	3	3
3
4	1	2	3	3
5	1	3	2	3
6	1	3	3	2
7	2	1	3	3
8	2	3	1	3
9	2	3	3	1
10	3	1	2	3
11	3	1	3	2
12	3	2	1	3
13	3	2	3	1
14	3	3	1	2
15	3	3	2	1
Master

Cell Formulas
Range	Formula
A4:D15	A4	=LET(d,A2:D2,c,COLUMNS(d),m,MID(BASE(SEQUENCE(c^c,,0),c,c),SEQUENCE(,c),1)+1,x,INDEX(d,FILTER(m,BYROW(m,LAMBDA(br,SUM(--(br=TOCOL(br)))=c)))),r,ROWS(x),b,BYROW(x,LAMBDA(br,CONCAT(br))),FILTER(x,MMULT((SEQUENCE(r)>=SEQUENCE(,r))*(b=TOROW(b)),SEQUENCE(r,,,0))=1))
Dynamic array formulas.

 

[excelNewbie22]

you are an asset to this forum!
thank you, again!

you solved my problem,
and still, if i may,
is it possible to generate them joined instead of 4 cells each one?
like in cell E2-1233 and in F2-1323 and in G2-1332 and so on...
i had to ask

 

[Fluff]

Yup, you can do that like

=LET(d,A2:D2,c,COLUMNS(d),m,MID(BASE(SEQUENCE(c^c,,0),c,c),SEQUENCE(,c),1)+1,x,INDEX(d,FILTER(m,BYROW(m,LAMBDA(br,SUM(--(br=TOCOL(br)))=c)))),r,ROWS(x),b,BYROW(x,LAMBDA(br,CONCAT(br))),TOROW(FILTER(b,MMULT((SEQUENCE(r)>=SEQUENCE(,r))*(b=TOROW(b)),SEQUENCE(r,,,0))=1)))

 

[excelNewbie22]

thanks............again !!

 

[Fluff]

You're welcome & thanks for the feedback.