Populate Date on Total Change

[sscornav]

I have the following spreadsheet. Users are allowed to update the yellow colored fields with their forecast. If the total changes (column E), I want to update column F with the current date/time and column G with the user name.

I could use some help with the macro. Thanks!

Excel Workbook
	A	B	C	D	E	F	G
1	1Q	2Q	3Q	4Q	Total	Date Changed	User Name
2	10.00	22.00	35.00	50.00	117.00
3	15.00	55.00	20.00	50.00	140.00
4	75.00	60.00	40.00	40.00	215.00
5	45.00	25.00	25.00	90.00	185.00
Sheet1

 

[hiker95]

sscornav,

You could use the Worksheet_Change Event for range A2:D5.


Sample data to begin with:

Excel Workbook
	A	B	C	D	E	F	G
1	1Q	2Q	3Q	4Q	Total	Date Changed	User Name
2					0
3					0
4					0
5					0
6
Sheet1

As the user enters data into range A2:D5 you get this:

Excel Workbook
	A	B	C	D	E	F	G
1	1Q	2Q	3Q	4Q	Total	Date Changed	User Name
2	10	22	35	50	117	05/24/2011 06:32:38 AM	hiker95001
3	15				15	05/24/2011 06:32:49 AM	hiker95001
4					0
5					0
6
Sheet1

Please TEST this FIRST in a COPY of your workbook (always make a backup copy before trying new code, you never know what you might lose).


1. Copy the below code, by highlighting the code and pressing the keys CTRL + C
2. Select the worksheet in which your code is to run
3. Right click on the sheet tab and choose View Code, to open the Visual Basic Editor
4. Where the cursor is flashing, paste the code by pressing the keys CTRL + V
5. Press the keys ALT + Q to exit the Editor, and return to Excel

Private Sub Worksheet_Change(ByVal Target As Range)
' hiker95, 05/24/2011
' http://www.mrexcel.com/forum/showthread.php?t=552211
If Intersect(Target, Range("A2:D5")) Is Nothing Then Exit Sub
If Target.Count > 1 Then Exit Sub
With Application
  .EnableEvents = False
  .ScreenUpdating = False
  
  Range("F" & Target.Row) = Format(Now, "mm/dd/yyyy hh:mm:ss AM/PM")
  Range("G" & Target.Row) = Environ("username")
  
  .EnableEvents = True
  .ScreenUpdating = True
End With
End Sub

Then make entries to individual cells in range A2:D5

 

[sscornav]

This works great if someone types in the range A2:D5, but if they copy/paste numbers or "clear contents" it misses the update.

Is there any way to key in on the value of the field column E, then populate Column F&G ?

 

[hiker95]

sscornav,

Are you only interested in range E2:E5 ?

 

[sscornav]

Yes. What I've found is that if the contents of a cell changes, the even works. if the cell has a formula in it and the value changes, it does not. Is there a way around this?

So essentially, if the Total changes in column E, I would like to populate the User and Date in the respective columns.

I appreciate your help!

 

[hiker95]

sscornav,


Let's try the Worksheet_Calculate Event.


Sample worksheet Sheet1 before any data is entered/pasted into:

Excel Workbook
	A	B	C	D	E	F	G
1	1Q	2Q	3Q	4Q	Total	Date Changed	User Name
2					0.00
3					0.00
4					0.00
5					0.00
6
Sheet1

After I paste in four rows of data:

Excel Workbook
	A	B	C	D	E	F	G
1	1Q	2Q	3Q	4Q	Total	Date Changed	User Name
2	10.00	22.00	35.00	50.00	117.00	5/24/2011 9:02	hiker95
3	15.00	55.00	20.00	50.00	140.00	5/24/2011 9:02	hiker95
4	75.00	60.00	40.00	40.00	215.00	5/24/2011 9:02	hiker95
5	45.00	25.00	25.00	90.00	185.00	5/24/2011 9:02	hiker95
6
Sheet1

Please TEST this FIRST in a COPY of your workbook (always make a backup copy before trying new code, you never know what you might lose).


1. Copy the below code, by highlighting the code and pressing the keys CTRL + C
2. Select the worksheet in which your code is to run
3. Right click on the sheet tab and choose View Code, to open the Visual Basic Editor
4. Where the cursor is flashing, paste the code by pressing the keys CTRL + V
5. Press the keys ALT + Q to exit the Editor, and return to Excel

Option Explicit
Private Sub Worksheet_Calculate()
' hiker95, 05/24/2011
' http://www.mrexcel.com/forum/showthread.php?t=552211
Dim c As Range
With Application
  .EnableEvents = False
  .ScreenUpdating = False
  For Each c In Me.Range("E2", Me.Range("E" & Rows.Count).End(xlUp))
    If c.Value <> 0 And c.Offset(, 1) = "" And c.Offset(, 2) = "" Then
      c.Offset(, 1) = Format(Now, "mm/dd/yyyy hh:mm:ss AM/PM")
      c.Offset(, 2) = Environ("username")
    End If
  Next c
  .EnableEvents = True
  .ScreenUpdating = True
End With
End Sub

 

[sscornav]

That doesn't seem to work either. If you clear out all the names and dates, go into the forecast for 1 row and update 1 number, all of the names and dates populate.

Can we key it off just the total value? If the total value changes for that row, we update the name and date, even if was populated.

Is there an event of dunction that detects if a value has changed?

 

[Andrew Poulsom]

There is no way to trap a change of a cell that contains a formula. The Worksheet_Change event should trap deletion and copy/paste, but Hiker95's code worked only if a single cell was modified. Try this variation:

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim Cell As Range
    If Intersect(Target, Range("A2:D5")) Is Nothing Then Exit Sub
    With Application
        .EnableEvents = False
        .ScreenUpdating = False
        For Each Cell In Target
            Range("F" & Cell.Row) = Format(Now, "mm/dd/yyyy hh:mm:ss AM/PM")
            Range("G" & Cell.Row) = Environ("username")
        Next Cell
        .EnableEvents = True
        .ScreenUpdating = True
    End With
End Sub

 

[sscornav]

Thank you very much! It works just great.

 

[sscornav]

The workbook is protected. Where would be the most efficient place to unprotect the workbook in the code? Assuming a password of "pmo".

There is another macro that protects all but the yellow cells:

Private Sub Worksheet_Activate()
Const TEST_CI As Long = 36 'light yellow

With Me
.Unprotect "pmo"
.Cells.Locked = True

For Each Cell In .UsedRange
If Cell.Interior.ColorIndex = TEST_CI Then
Cell.Locked = False
End If
Next Cell

.Protect Password:="pmo", Scenarios:=True
End With
End Sub