PopUp InPutBox Again

[Prasad K]

Here i used this vba to unprotect sheet by inputbox

here what i want if type wrong password then a msgbox will popup and show me message (wrong password) then i click ok
the inputbox will be get popup again to enter correct password after i enter correct password then show me another msgbox (sheet unprotect successfully)

Sub UnProtect()

Dim ws As Worksheet
Dim pwd As String
Dim myValue As Variant
pwd = "123" ' Put your password here
myValue = InputBox("What is the password?")
If myValue = pwd Then
    For Each ws In Worksheets
        ws.UnProtect Password:=pwd
    Next ws
Else
   MsgBox "Wrong Password"
End If

End Sub

 

[dmt32]

Hi
try

Sub Unprotect()
    Dim Entry       As Variant
    Dim strPrompt   As String, strTitle As String
    Dim try         As Long
    Dim ws          As Worksheet
  
    Const strPassword As String = "123"
  
    try = 1
    strTitle = "Enter Password"
    Do
        strPrompt = "Please Enter Password"
        strPrompt = strPrompt & Chr(10) & Chr(10) & _
                 "attempt " & try & " of 3"
      
        Entry = InputBox(strPrompt, strTitle)
        'cancel pressed
        If StrPtr(Entry) = 0 Then Exit Do
      
        If Entry <> strPassword And try = 3 Then
            MsgBox "Three Attempts Only Allowed", 16, "Three Attempts Only"
            Exit Do
        ElseIf Entry <> strPassword Then
            MsgBox "Password invalid - Please try again", 48, "Invalid Password"
            try = try + 1
          
        Else
          
            MsgBox "Password Correct - Click OK To Continue.", 48, "Password Correct"
          
            Exit Do
        End If
      
    Loop
    For Each ws In Worksheets
        ws.Unprotect Password:=Entry
    Next ws
End Sub

Dave

 

[Prasad K]

Hi
try

Sub Unprotect()
    Dim Entry       As Variant
    Dim strPrompt   As String, strTitle As String
    Dim try         As Long
    Dim ws          As Worksheet
 
    Const strPassword As String = "123"
 
    try = 1
    strTitle = "Enter Password"
    Do
        strPrompt = "Please Enter Password"
        strPrompt = strPrompt & Chr(10) & Chr(10) & _
                 "attempt " & try & " of 3"
     
        Entry = InputBox(strPrompt, strTitle)
        'cancel pressed
        If StrPtr(Entry) = 0 Then Exit Do
     
        If Entry <> strPassword And try = 3 Then
            MsgBox "Three Attempts Only Allowed", 16, "Three Attempts Only"
            Exit Do
        ElseIf Entry <> strPassword Then
            MsgBox "Password invalid - Please try again", 48, "Invalid Password"
            try = try + 1
         
        Else
         
            MsgBox "Password Correct - Click OK To Continue.", 48, "Password Correct"
         
            Exit Do
        End If
     
    Loop
    For Each ws In Worksheets
        ws.Unprotect Password:=Entry
    Next ws
End Sub

Dave

Thank you so much it's working

in 3rd attempt of wrong password i have Run-time Error on this line ws.Unprotect Password:=Entry

 

[dmt32]

Hi,

sorry my error

Sub Unprotect()
    Dim Entry       As Variant
    Dim strPrompt   As String, strTitle As String
    Dim try         As Long
    Dim ws          As Worksheet
    
    Const strPassword As String = "123"
    
    try = 1
    strTitle = "Enter Password"
    Do
        strPrompt = "Please Enter Password To Continue"
        strPrompt = strPrompt & Chr(10) & Chr(10) & _
                 "attempt " & try & " of 3"
        
        Entry = InputBox(strPrompt, strTitle)
        If StrPtr(Entry) = 0 Then Exit Sub
        
        If Entry <> strPassword And try = 3 Then
            MsgBox "Three Attempts Only Allowed", 16, "Three Attempts Only"
            Exit Sub
        ElseIf Entry <> strPassword Then
            MsgBox "Password invalid - Please try again", 48, "Invalid Password"
            try = try + 1
            
        Else
            
            MsgBox "Password Correct - Click OK To Continue.", 48, "Password Correct"
            
            Exit Do
        End If
        
    Loop
    For Each ws In Worksheets
        ws.Unprotect Password:=Entry
    Next ws
End Sub

Dave