Print only visible Filtered Rows from Excel Table

[JohnZ1156]

Runing MS Excel 2021.

I have an Excel table. I have a macro that will print out the last 45 rows of the table.
I would like to be able to print out the last 45 visible rows of a "filtered" table.
Now, it only prints out the visible rows within the last 45 rows.

Sub RegisterPrint()

'    Call ShowAllPrinters
    Application.ScreenUpdating = False
    Application.ActivePrinter = "HP Officejet Pro 8600 (Network) on NE02:"
    Application.Dialogs(xlDialogPrinterSetup).Show

    ActiveSheet.PageSetup.PrintArea = ""

    Dim MyLastRow As String

    MyLastRow = Range("A65536").End(xlUp).Row
    Range("A" & (MyLastRow - 44) & ":K" & MyLastRow).Select
'Put paste code down here

    ActiveSheet.PageSetup.PrintArea = Selection.Address
'    Application.Dialogs(xlDialogPrinterSetup).Show

'Worksheets("Sheet1").Activate
'ActiveSheet.PageSetup.PrintArea = _
'ActiveCell.CurrentRegion.Address

,    Call RegisterHeader
    
   ActiveWindow.SelectedSheets.PrintOut Copies:=1, Preview:=True, Collate:=True, _
        IgnorePrintAreas:=False
'    ActiveSheet.PageSetup.PrintArea = ""

    Range("B1048576").End(xlUp).Select
    ActiveCell.Offset(1, 0).Select

    Call Change_Font
'-------------------------------------
    Range("A1048576").End(xlUp).Select
    ActiveCell.Offset(-16, 0).Select
    Application.Goto ActiveCell, Scroll:=True
    ActiveCell.End(xlDown).Select
    ActiveCell.Offset(1, 1).Select
    
    Application.ActivePrinter = "HP Officejet Pro 8600 (Network) on NE02:"

    
    Application.ScreenUpdating = True
End Sub

 

[DanteAmor]

Try this:

Sub RegisterPrint()
    Dim MyLastRow As Long, i As Long, n As Long, StartRow As Long

'    Call ShowAllPrinters
    Application.ScreenUpdating = False
    Application.ActivePrinter = "HP Officejet Pro 8600 (Network) on NE02:"
    Application.Dialogs(xlDialogPrinterSetup).Show

    ActiveSheet.PageSetup.PrintArea = ""
    MyLastRow = Range("A" & Rows.Count).End(xlUp).Row
    n = 0
    StartRow = 1
    For i = MyLastRow To 1 Step -1
      If Range("A" & i).EntireRow.Hidden = False Then
        n = n + 1
        If n = 45 Then
          StartRow = i
          Exit For
        End If
      End If
    Next
    
    ActiveSheet.PageSetup.PrintArea = Range("A" & StartRow & ":K" & MyLastRow).Address
'    Application.Dialogs(xlDialogPrinterSetup).Show

'Worksheets("Sheet1").Activate
'ActiveSheet.PageSetup.PrintArea = _
'ActiveCell.CurrentRegion.Address

    Call RegisterHeader
    
   ActiveWindow.SelectedSheets.PrintOut Copies:=1, Preview:=True, Collate:=True, _
        IgnorePrintAreas:=False
'    ActiveSheet.PageSetup.PrintArea = ""

    Range("B1048576").End(xlUp).Select
    ActiveCell.Offset(1, 0).Select

    Call Change_Font
'-------------------------------------
    Range("A1048576").End(xlUp).Select
    ActiveCell.Offset(-16, 0).Select
    Application.Goto ActiveCell, Scroll:=True
    ActiveCell.End(xlDown).Select
    ActiveCell.Offset(1, 1).Select
    
    Application.ActivePrinter = "HP Officejet Pro 8600 (Network) on NE02:"

    
    Application.ScreenUpdating = True
End Sub

 

[JohnZ1156]

Hi DanteAmor,
Thank you for your quick response.
Your suggestion works great with one minor detail, which was absolutely NOT your fault.
I neglected to mention that my table headers start in row 17.
If my filter returns less than 45 rows of data, it includes rows above the table, (ex. rows 1-16)
Changes: I made the Start Row = 17

Last: I want to exclude column A from the printout report.
Changes: ActiveSheet.PageSetup.PrintArea = Range("B" & StartRow & ":K" & MyLastRow).Address

Works great!
Thank you.