Private sub question

[Vtookup]

Hi.
I want to check cell if A2>A1.
If its true then A2 will turn blank for user to re-enter. And if it's false, then do nothing.
This Workbook will only have one sheet.
I have used If, Then, End if, Else. but without success. I fall short on Do Nothing code.
Question, What private sub ??? (Declaration?) and need help how to write the code?
Thanks in advance.

 

[My Aswer Is This]

Try this:

Sub My_Sub()
If Range("A2").Value > Range("A1").Value Then Range("A2").Value = ""
End Sub

 

[kevin9999]

I think I'm interpreting the requirement differently - the following code should be put in the sheet code module of the sheet in question. It will trigger automatically when A2's value changes via input:

Private Sub Worksheet_Change(ByVal Target As Range)
    If Not Intersect(Target, Range("A2")) Is Nothing Then
        If Not IsNumeric(Target.Value) Then
            MsgBox "Enter numbers only in cell A2"
            Target = vbNullString
            Target.Select
            Exit Sub
        End If
        
        If Target > Target.Offset(-1) Then
            MsgBox "Enter a number smaller than A1's value"
            Target = vbNullString
            Target.Select
        End If
    End If
End Sub

 

[bebo021999]

This code is worksheet module (not general module). It will be triggered any change in specific range in sheet.

Right click on tab's name, View Code, then paste it into

Option Explicit
Private Sub Worksheet_Change(ByVal Target As Range)
Dim rng As Range
Set rng = Range("A2:B100") ' adjust to the actual input range
If Intersect(Target, rng) Is Nothing Then Exit Sub
If IsNumeric(Target) And Target <= Target.Offset(-1) Then Exit Sub
Target = ""
End Sub

 

[My Aswer Is This]

If this was to be a Worksheet change again script I would do it this way.

Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Address = "$A$2" Then
If Target.Value > Target.Offset(-1, 0).Value Then
Target.Value = ""
Target.Select
End If

End If
End Sub

 

[Vtookup]

Hi All,
My Aswer Is This, kevin9999 and bebo021999
Thanks for the help. All codes works.
It made my day. Nice touch with Target.Select
Thank You.

 

[kevin9999]

Hi All,
My Aswer Is This, kevin9999 and bebo021999
Thanks for the help. All codes works.
It made my day. Nice touch with Target.Select
Thank You.

Glad we could help, and thanks for the feedback