Problem with Code

[MarkAndrews]

I have the following code in place (Workbook_BeforeClose)

However - It does not like the following line

' get the chart sheets
For Each cht In ThisWorkbook

There are 18 charts in this workbook - Any Idea's?

TIA

Sub PrintAllCharts()
    
  Application.ScreenUpdating = False
  Dim ws As Worksheet
  Dim chob As ChartObject
  Dim cht As Chart
  Dim vbAns As Long

  vbAns = MsgBox("Do you want to print all charts?", vbQuestion + vbYesNo)
  
  If vbAns <> vbYes Then GoTo ExitSub

  ' get the chart sheets
  For Each cht In ThisWorkbook
    cht.PrintOut
    ' get any charts embedded in the chart sheet
    For Each chob In cht.ChartObjects
      chob.Chart.PrintOut
      DoEvents
    Next
  Next
  
  ' now get all charts embedded on all worksheets
  For Each ws In ThisWorkbook.Worksheets
    For Each chob In ws.ChartObjects
      chob.Chart.PrintOut
      DoEvents
    Next
  Next
  
ExitSub:
  Application.ScreenUpdating = True
  End Sub

 

[lozzablake]

try

For Each cht In ThisWorkbook.Charts

you must always have the collection in the For statement

 

[Richard Schollar]

Mark

Try:

For Each cht in ThisWorkbook.Charts

Best regards

Richard

 

[MarkAndrews]

Excellent, Thanks v much guys!

You've saved my *** again!