Produce Combinations

[Cobber2008]

I have a table with 4 columns with number in them. i want to be able to produce all the various combinations as per what i started in the combination column. Any idea how to do this thank you.

A	B	C	D		Combinations
1	5	1	5		1-5-1-5
2	3	9	3		1-3-1-5
12	13	3	6		1-13-1-5
4	2	11	9		1-2-1-5
15	7	12	1		.
6	1	5	2		.
					.
					6-1-5-2

 

[SunnyAlv]

Try this

=TEXTJOIN("-",,$A$1,B1,C$1$:$D$1)

 

[Cobber2008]

Hi Sunny thanks for the reply - that gives the first combinations but not what i am after but i think i solved it.

 

[smozgur]

i think i solved it.

Good to hear you solved it.
If you would like to post the solution then it is perfectly fine to mark your post as the solution to help future readers. Otherwise, please do not mark a post that doesn't contain a solution.

 

[Cobber2008]

oK this is what i have used - INDEX(A:A, INT((ROW()-1)/(COUNTA(B:B)*COUNTA(C:C)*COUNTA(D:D)))+1) & INDEX(B:B, MOD(INT((ROW()-1)/(COUNTA(C:C)*COUNTA(D:D))), COUNTA(B:B))+1) & INDEX(C:C, MOD(INT((ROW()-1)/COUNTA(D:D)), COUNTA(C:C))+1) & INDEX(D:D, MOD(ROW()-1, COUNTA(D:D))+1)

 

[Fluff]

As you have 365 another option is

Fluff.xlsm
	A	B	C	D	E	F
1	A	B	C	D
2	1	5	1	5		1-5-1-5
3	2	3	9	3		1-5-1-3
4	12	13	3	6		1-5-1-6
5	4	2	11	9		1-5-1-9
6	15	7	12	1		1-5-1-1
7	6	1	5	2		1-5-1-2
8						1-5-9-5
9						1-5-9-3
10						1-5-9-6
11						1-5-9-9
12						1-5-9-1
13						1-5-9-2
14						1-5-3-5
15						1-5-3-3
16						1-5-3-6
17						1-5-3-9
18						1-5-3-1
19						1-5-3-2
20						1-5-11-5
21						1-5-11-3
22						1-5-11-6
23						1-5-11-9
24						1-5-11-1
25						1-5-11-2
26						1-5-12-5
27						1-5-12-3
28						1-5-12-6
29						1-5-12-9
30						1-5-12-1
31						1-5-12-2
32						1-5-5-5
Sheet6

Cell Formulas
Range	Formula
F2:F1297	F2	=LET(d,A2:D7,r,ROWS(d),c,COLUMNS(d),s,SEQUENCE(,c),b,MID(BASE(SEQUENCE(r^c,,0),r,c),s,1)+1,BYROW(INDEX(d,b,s),LAMBDA(br,TEXTJOIN("-",,br))))
Dynamic array formulas.

 

[Cobber2008]

Thanks Fluff does that do every combination?

 

[Fluff]

Yes, I just showed the 1st few rows. Try it & see.

 

[Cobber2008]

Yes works great thanks a lot Fluff.

 

[Fluff]

You're welcome & thanks for the feedback.